whichwayisup-0.7.0.ebuild

whichwayisup-0.7.0.ebuild (text/plain), 1.49 KB, created by Denilson Sá Maia on 2007-05-29 08:28:40 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games python

MY_PV=${PV//./}
MY_P=${PN}_b${MY_PV}
DESCRIPTION="A traditional and challenging 2D platformer game with a slight rotational twist"
HOMEPAGE="http://hectigo.net/puskutraktori/whichwayisup/"
SRC_URI="http://hectigo.net/puskutraktori/whichwayisup/${MY_P}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=dev-lang/python-2.4
	>=dev-python/pygame-1.6"
DEPEND="app-arch/unzip"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${P}"-gentoo.patch
	sed -i -e "s:@GENTOO_LIBDIR@:$(games_get_libdir)/${PN}:" \
		run_game.py || die "Changing library path failed"
	sed -i -e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
		lib/data.py || die "Changing data path failed"
}

src_install() {
	newgamesbin run_game.py ${PN} || die "newgamesbin failed"

	insinto "$(games_get_libdir)/${PN}"
	doins lib/*.py || die "doins lib failed"

	dodoc README.txt changelog.txt

	insinto "${GAMES_DATADIR}/${PN}"
	doins -r data/* || die "doins data failed"

	newicon "${FILESDIR}/${PN}"-64.png "${PN}"-64.png
	newicon "${FILESDIR}/${PN}"-48.png "${PN}"-48.png
	newicon "${FILESDIR}/${PN}"-32.png "${PN}"-32.png
	make_desktop_entry ${PN} "Which Way Is Up" "${PN}"-64.png
	prepgamesdirs
}

pkg_postinst() {
	python_version
	python_mod_optimize "$(games_get_libdir)/${PN}"
}

pkg_postrm() {
	python_version
	python_mod_cleanup "$(games_get_libdir)/${PN}"
}