pygtksourceview-2.16.0.ebuild

pygtksourceview-2.16.0.ebuild (text/plain), 1.55 KB, created by René 'Necoro' Neumann on 2007-03-31 22:22:26 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

WANT_AUTOCONF=latest
WANT_AUTOMAKE=1.9
inherit distutils gnome2 python virtualx autotools

DESCRIPTION="provides the gtksourceview-widget for pygtk"
HOMEPAGE="http://pygtk.org/"

ORIG_GNOME_P="gnome-python-desktop"
ORIG_GNOME_PV="${ORIG_GNOME_P}-${PV}"
SRC_URI="mirror://gnome/sources/${ORIG_GNOME_P}/${PVP[0]}.${PVP[1]}/${ORIG_GNOME_PV}.tar.${GNOME_TARBALL_SUFFIX}"

LICENSE="LGPL-2.1 GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sh sparc x86"

RDEPEND="virtual/python
	>=dev-python/pygtk-2.4.0
	>=dev-libs/glib-2.6.0
	>=x11-libs/gtk+-2.4.0
	>=dev-python/gnome-python-2.10.0
	>=x11-libs/gtksourceview-1.1.90
	!dev-python/gnome-python-desktop"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.7"

DOCS="AUTHORS ChangeLog INSTALL MAINTAINERS NEWS README"

S="${WORKDIR}/${ORIG_GNOME_PV}"

src_unpack () {
	gnome2_src_unpack

	# disable all plugins except GTKSOURCEVIEW and GNOMEPRINT
	# (the latter is needed by GTKSOURCEVIEW)
	sed -i 	-e 's/\(build_[a-z_]\+=\)true,/\1false,/g' \
			-e 's/\(build_gtksourceview=\)false,/\1true,/' \
			-e 's/\(build_gnomeprint=\)false,/\1true,/' \
			configure.ac

	eautoreconf
}

src_test() {
	Xmake check || die "tests failed"
}

src_install() {
	gnome2_src_install

	if use doc; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}

pkg_postinst() {
	python_version
	python_mod_optimize ${ROOT}/usr/$(get_libdir)/python${PYVER}/site-packages/gtk-2.0
}

pkg_postrm() {
	python_version
	python_mod_cleanup
}