mysql-gui-tools-5.0_p10.ebuild

mysql-gui-tools-5.0_p10.ebuild (text/plain), 2.15 KB, created by Rick Harris on 2007-03-08 08:32:57 UTC

GCONF_DEBUG="no"

inherit gnome2 eutils flag-o-matic

MY_P="${P/_p/r}"

DESCRIPTION="MySQL GUI Tools"
HOMEPAGE="http://www.mysql.com/products/tools/"
SRC_URI="mirror://mysql/Downloads/MySQLGUITools/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="nls"

RDEPEND=">=x11-libs/gtk+-2.6
	>=dev-libs/glib-2.6
	>=gnome-base/libglade-2.5
	>=dev-libs/libsigc++-2.0
	>=dev-libs/libpcre-4.4
	>=dev-libs/libxml2-2.6.2
	=dev-cpp/glibmm-2.12*
	=dev-cpp/gtkmm-2.10*
	=gnome-extra/gtkhtml-3.12*
	>=virtual/mysql-5.0
	dev-lang/lua
	virtual/opengl"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.15
	>=app-text/scrollkeeper-0.3.11"
RDEPEND="${RDEPEND}
	!dev-db/mysql-administrator
	!dev-db/mysql-query-browser"

S="${WORKDIR}"/${MY_P}

src_unpack() {
	gnome2_src_unpack
	cd "${S}"

	epatch "${FILESDIR}"/mysql-gui-tools-5.0_p8-i18n-fix.patch
	epatch "${FILESDIR}"/mysql-gui-tools-5.0_p8-lua-modules.patch
}

src_compile() {
	# mysql has -fno-exceptions, but we need exceptions
	append-flags -fexceptions

	cd "${S}"/mysql-gui-common

	## Disable linking against the deprecated -ltermcap this is now handled by -lncurses ##
	sed -i -e 's:-ltermcap::g' tools/{grtsh,grtsh3}/Makefile{.am,.in} || die "Sed failed"

	gnome2_src_configure $(use_enable nls i18n) --enable-grt --enable-canvas
	! use nls && \
		sed -i -e \
			's:source res images po:source res images:g' Makefile.in \
				|| die "Sed failed on Makefile.in"
	emake || die "compile failure"

	cd "${S}"/mysql-administrator
	gnome2_src_configure $(use_enable nls i18n)
	! use nls && \
		sed -i -e \
			's:source res images po:source res images:g' Makefile.in \
				|| die "Sed failed on Makefile.in"
	emake || die "compile failure"

	cd "${S}"/mysql-query-browser
	gnome2_src_configure --with-gtkhtml=libgtkhtml-3.8
	! use nls && \
		sed -i -e \
			's:source res images po:source res images:g' Makefile.in \
				|| die "Sed failed on Makefile.in"
	emake || die "compile failure"

	cd "${S}"/mysql-workbench
	gnome2_src_compile
}

src_install() {
	cd "${S}"/mysql-gui-common
	gnome2_src_install

	cd "${S}"/mysql-administrator
	gnome2_src_install

	cd "${S}"/mysql-query-browser
	gnome2_src_install

	cd "${S}"/mysql-workbench
	gnome2_src_install
}