slib-3.1.4-r1.ebuild

slib-3.1.4-r1.ebuild (text/plain), 1.86 KB, created by Brice Arnould (un_brice) on 2007-01-29 12:53:46 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/slib/slib-3.1.4-r1.ebuild,v 1.1 2007/01/24 16:59:50 hkbst Exp $

inherit versionator eutils

#version magic thanks to masterdriverz and UberLord using bash array instead of tr
trarr="0abcdefghi"
MY_PV="$(get_version_component_range 1)${trarr:$(get_version_component_range 2):1}$(get_version_component_range 3)"

MY_P=${PN}${MY_PV}
S=${WORKDIR}/${PN}
DESCRIPTION="library providing functions for Scheme implementations"
SRC_URI="http://swiss.csail.mit.edu/ftpdir/scm/${MY_P}.zip"

HOMEPAGE="http://swiss.csail.mit.edu/~jaffer/SLIB"

SLOT="0"
LICENSE="public-domain BSD"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc x86"
IUSE="guile bigloo"

#unzip for unpacking
#depend on guile for now, until slib actually works with another scheme implementation in portage
RDEPEND="guile? ( ~dev-scheme/guile-1.6.8 )
	bigloo? ( dev-scheme/bigloo )"
DEPEND="app-arch/unzip
	${RDEPEND}"

# slib tests rely on scm being installed. It isn't even in portage :(
RESTRICT="test"

# maybe also do "make infoz"

src_install() {
	insinto /usr/share/slib/ #don't install directly into guile dir
	doins *.scm
	doins *.init
	dodoc ANNOUNCE ChangeLog FAQ README
	doinfo slib.info
	use guile && dosym /usr/share/slib/ /usr/share/guile/slib # link from guile dir
}

pkg_postinst() {
	export SCHEME_LIBRARY_PATH="/usr/share/slib/"
	if use guile; then
		einfo "Generating slibcat for guile..."
		chroot ${ROOT} \
			/usr/bin/guile -l /usr/share/slib/guile.init -c \
			"(use-modules (ice-9 slib)) \
			(define sub-vicinity (lambda (vic name) (string-append vic name \".scm\"))) \
			(require 'new-catalog)"
	fi
	if use bigloo; then
		einfo "Generating slibcat for bigloo..."
		echo "(require 'new-catalog)" | \
			chroot ${ROOT} /usr/bin/bigloo -load /usr/share/slib/bigloo.init
	fi
}