doom1-data-1.0.ebuild

doom1-data-1.0.ebuild (text/plain), 2.06 KB, created by Brandon Captain on 2007-01-16 03:21:59 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit eutils games

DESCRIPTION="Doom1 data files"
HOMEPAGE="http://www.idsoftware.com/"
SRC_URI=""

LICENSE="DOOM1"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="doc"

DEPEND=""
# a client is required to play the game. prboom is preferred because it is stable on amd64, while doomsday is not.
RDEPEND=" || (games-fps/prboom
		games-fps/doomsday)"

S=${WORKDIR}

pkg_setup() {
	export CDROM_NAME_SET=("Existing Install" "Ultimate Doom CD" "Doom Collector's Edition CD")
	cdrom_get_cds doom.wad:DOOM/DOOMCD/DOOM.WAD:Setup/Ultimate\ Doom/doom.wad

	if [[ $CDROM_SET -ne 0 && $CDROM_SET -ne 1 && $CDROM_SET -ne 2 ]] ; then
		die "Error locating data files.";
	fi
}

src_unpack() {
	case ${CDROM_SET} in
		0) cp ${CDROM_ROOT}/doom.wad ${S}/doom.wad || die "Error copying doom.wad.";;
		1) cp ${CDROM_ROOT}/DOOM/DOOMCD/DOOM.WAD ${S}/doom.wad || die "Error copying DOOM.WAD.";;
		2) cp ${CDROM_ROOT}/Setup/Ultimate\ Doom/doom.wad ${S}/doom.wad || die "Error copying doom.wad.";;
	esac
}

src_install() {
	dodir ${GAMES_DATADIR}/doom-data
	insinto ${GAMES_DATADIR}/doom-data

	doins ${S}/doom.wad || die "Error installing doom.wad.";

	if use doc ; then
		if [[ ${CDROM_SET} -eq 2 ]] ; then
			dodoc ${CDROM_ROOT}/Setup/readme.rtf || die "Error installing readme.rtf";
			dodoc ${CDROM_ROOT}/Setup/license.txt || die "Error installing license.txtt";
		fi
		if [[ ${CDROM_SET} -eq 1 ]] ; then
			dodoc ${CDROM_ROOT}/README.DOC || die "Error installing README.DOC";
			dodoc ${CDROM_ROOT}/LICENSE.DOC || die "Error installing LICENSE.DOC";
		fi
		if [[ ${CDROM_SET} -eq 0 ]] ; then
			dodoc ${CDROM_ROOT}/readme.doc || \
			dodoc ${CDROM_ROOT}/README.DOC || \
			dodoc ${CDROM_ROOT}/Setup/readme.rtf || \
			dodoc ${CDROM_ROOT}/readme.rtf || \
			die "Error installing documentation.";

			dodoc ${CDROM_ROOT}/license.doc || \
			dodoc ${CDROM_ROOT}/LICENSE.DOC || \
			dodoc ${CDROM_ROOT}/Setup/license.txt || \
			dodoc ${CDROM_ROOT}/license.txt || \
			die "Error installing documentation.";
		fi
	fi

	prepgamesdirs
}