gambit-4.0_beta20.ebuild

gambit-4.0_beta20.ebuild (text/plain), 1.89 KB, created by Brice Arnould (un_brice) on 2007-01-10 03:22:59 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/gambit/gambit-4.0_beta15.ebuild,v 1.2 2006/10/10 08:29:07 joslwah Exp $
inherit eutils elisp-common

MY_PN=gambc
MY_PV=${PV//_beta/b}

DESCRIPTION="Gambit-C is a native Scheme to C compiler and interpreter."
HOMEPAGE="http://www.iro.umontreal.ca/~gambit/"
SRC_URI="http://www.iro.umontreal.ca/~gambit/download/gambit/4.0/source/${MY_PN}-${MY_PV}.tar.gz"

LICENSE="Apache-2.0 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"

IUSE="emacs examples gcc-opts"
DEPEND="emacs? ( virtual/emacs )"
SITEFILE="50gambit-gentoo.el"

S=${WORKDIR}/${MY_PN}-${MY_PV}

src_compile() {
	# binaries have install location hardcoded, so we tell the true place,
	# since we don't use the install target of the makefile anyway
	sed 's/PACKAGE_SUBDIR=.*/PACKAGE_SUBDIR=\//' -i configure
	econf --enable-shared --enable-single-host --enable-char-size=2 \
		--prefix=/usr/ $(use_enable gcc-opts) || die
	emake -j1 || die "emake failed" # -j1 because build process takes 512mb per gcc

	cd misc
	if use emacs; then
		elisp-comp *.el
	fi
}

src_install() {
	# make install is too messed up
	dobin gsi/gsi bin/gsc-cc-o
	newbin gsc/gsc gsc-gambit
	dolib misc/syntax-case.scm lib/*.scm lib/_gambc.c lib/libgambc.so
	doinfo doc/gambit-c.info*
	insinto /usr/include ; doins include/gambit.h

	dosym gsc-gambit /usr/bin/gsc-script
	for fn in gsi-script scheme-ieee-1178-1990 scheme-r4rs scheme-r5rs \
		scheme-srfi-0 six six-script ; do
		dosym gsi /usr/bin/${fn}
	done

	if use emacs; then
		elisp-install ${PN} misc/*.{el,elc}
		elisp-site-file-install ${FILESDIR}/${SITEFILE}
	fi
	dodoc INSTALL.txt README
	dodoc doc/gambit-c.{txt,pdf,html}
	if use examples ; then
		insinto /usr/share/doc/${PF}
		find examples -type f \( -name makefile -o -name makefile.in \) \
			-exec rm -f '{}' \; ;
		doins -r examples
	fi
}