ZSNES 1.50 ebuild

zsnes-1.50.ebuild (text/plain), 1.74 KB, created by Kiyoshi Aman on 2007-01-06 21:56:05 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"
inherit eutils autotools flag-o-matic multilib games

MY_P="${PN}${PV/'.'/}"
DESCRIPTION="SNES (Super Nintendo) emulator that uses x86 assembly"
HOMEPAGE="http://www.zsnes.com/ http://ipherswipsite.com/zsnes/"
SRC_URI="mirror://sourceforge/zsnes/${MY_P}src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="debug debugger opengl png"

RDEPEND=">=media-libs/libsdl-1.2.0
	>=sys-libs/zlib-1.1
	amd64? ( app-emulation/emul-linux-x86-sdl )
	opengl? ( virtual/opengl )
	png? ( media-libs/libpng )
	debugger? ( sys-libs/ncurses )"
DEPEND="${RDEPEND}
	>=dev-lang/nasm-0.98
	sys-devel/automake
	>=sys-devel/autoconf-2.58"

S="${WORKDIR}/${PN}_${PV//./_}"

pkg_setup() {
	games_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"/src
	cp "icons/48x48x32.png" "${T}/zsnes.png"
	epatch "${FILESDIR}"/${PV}-configure.patch
	eautoreconf || die
}

src_compile() {
	use amd64 && multilib_toolchain_setup x86
	cd src
	if use debug ; then
		egamesconf				\
			$(use_enable png libpng)	\
			$(use_enable opengl)		\
			$(use_enable debug)		\
			$(use_enable debugger)		\
			force_arch=no			\
			|| die
	else
		egamesconf \
			--enable-release		\
			$(use_enable png libpng)	\
			$(use_enable opengl)		\
			$(use_enable debugger)		\
			force_arch=no			\
			|| die
	fi
	emake || die "emake failed"
}

src_install() {
	dogamesbin src/${ZSNES_BIN} || die "dogamesbin failed"
	newman src/linux/zsnes.1 zsnes.6
	dodoc docs/{*.txt,README.LINUX} 
	dohtml -r docs/Linux/*
	if use debug ; then
		make_desktop_entry zsnesd ZSNES zsnes.png
	else
		domenu src/linux/zsnes.desktop
	fi
	doicon "${T}/zsnes.png"
	prepgamesdirs
}