quetoo-0.6.0.ebuild

quetoo-0.6.0.ebuild (text/plain), 1.07 KB, created by Paul Bredbury on 2007-01-01 23:09:25 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils games

DESCRIPTION="Quake 2 performance engine"
HOMEPAGE="http://jdolan.dyndns.org/jaydolan/quetoo.html"
SRC_URI="http://jdolan.dyndns.org/jaydolan/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
# Works on amd64 - http://bugs.gentoo.org/show_bug.cgi?id=154292
KEYWORDS="~amd64 ~x86"
IUSE="alsa mysql"

RDEPEND="alsa? ( media-libs/alsa-lib )
	virtual/opengl
	media-libs/libsdl"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	eautoreconf
}

src_compile() {
	egamesconf \
		$(use_with alsa) \
		$(use_with mysql) \
		|| die "egamesconf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	make_desktop_entry ${PN} "Quetoo"

	dodoc README

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Be warned, there is no user interface in this game."
	elog "To start a map, type e.g.:  map base1"
	elog "The configuration is saved in ~/.quake2/baseq2/quetoo.cfg"
	echo
}