gtkam-0.1.14.ebuild

gtkam-0.1.14.ebuild (text/plain), 1.05 KB, created by Samuli Suominen (RETIRED) on 2007-01-01 03:13:27 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

WANT_AUTOCONF="2.5"
WANT_AUTOMAKE="1.9"

inherit autotools eutils gnome2

DESCRIPTION="A frontend for gPhoto 2"
HOMEPAGE="http://gphoto.org/proj/gtkam"
SRC_URI="mirror://sourceforge/gphoto/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="gimp gnome nls"

RDEPEND=">=x11-libs/gtk+-2
	>=media-libs/libgphoto2-2.1.4
	>=media-libs/libexif-0.3.2
	media-libs/libexif-gtk
	gnome? ( >=gnome-base/libbonobo-2 >=gnome-base/libgnomeui-2 )
	gimp? ( >=media-gfx/gimp-2 )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

DOCS="ChangeLog ABOUT-NLS AUTHORS NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF} \
		$(use_enable nls) \
		$(use_with gimp) \
		$(use_with gnome) \
		$(use_with gnome bonobo) \
		--with-rpmbuild=/bin/false"
}

src_unpack() {
	gnome2_src_unpack
	epatch ${FILESDIR}/${PN}-asneeded.patch
	eautoconf
	eautomake
}

src_install() {
	gnome2_src_install
	rm -rf ${D}/usr/share/doc/gtkam
}