0.7.2.3 expanded to install for seamonkey and/or firefox based on USE vars

adblock_plus-0.7.2.3-r1.ebuild (text/plain), 2.41 KB, created by Jeff Huffman on 2006-12-23 15:59:59 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils multilib

DESCRIPTION="Adblock Plus, enhanced adblocker for Firefox"
HOMEPAGE="http://adblockplus.org/"
SRC_URI="http://releases.mozilla.org/pub/mozilla.org/extensions/adblock_plus/${P}-fx+fl+zm+tb.xpi"

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~sparc ~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE="firefox seamonkey"

RDEPEND="firefox? ( >=www-client/mozilla-firefox-1.5.0.7 ) seamonkey? ( >=www-client/seamonkey-1.0.0 )"
DEPEND="${RDEPEND} app-arch/unzip"

S=${WORKDIR}

xpi_unpack() {
	local xpi xpiname srcdir

	# Not gonna use ${A} as we are looking for a specific option being passed to function
	# You must specify which xpi to use
	[[ -z "$*" ]] && die "Nothing passed to the $FUNCNAME command. please pass which xpi to unpack"

	for xpi in "$@"; do
		einfo "Unpacking ${xpi} to ${PWD}"
		xpiname=${xpi%.*}

		if   [[ "${xpi:0:2}" != "./" ]] ; then
			srcdir="${DISTDIR}/"
		fi

		[[ -s "${srcdir}${xpi}" ]] ||  die "${xpi} does not exist"

		case "${xpi##*.}" in
			ZIP|zip|jar|xpi)
				mkdir -p "${WORKDIR}/${xpiname}" && \
					cd "${WORKDIR}/${xpiname}" && \
					unzip -qo "${srcdir}${xpi}" ||  die "failed to unpack ${xpi}"
				;;
			*)
				einfo "unpack ${xpi}: file format not recognized. Ignoring."
				;;
		esac
	done
}

xpi_install() {
	local emid

	# You must tell xpi_install which xpi to use
	[[ ${#} -ne 1 ]] && die "$FUNCNAME takes exactly one argument, please specify an xpi to unpack"

	x="${1}"
	cd ${x}
	if [ ${INSTALL_FOR} == "firefox" ]; then
		# determine id for extension
		emid=$(sed -n -e '/<\?em:id>\?/!d; s/.*\([\"{].*[}\"]\).*/\1/; s/\"//g; p; q' ${x}/extensions/emid/install.rdf) || die "failed to determine extension id"
		insinto "${MOZILLA_FIVE_HOME}/extensions/${emid}"
	elif [ ${INSTALL_FOR} == "seamonkey" ]; then
		rm install.js install.rdf chrome.manifest
		mv defaults/preferences defaults/pref
		touch .autoreg
		insinto "${MOZILLA_FIVE_HOME}"
	fi
	doins -r "${x}"/{.,}[^.]* || die "failed to copy extension"
}

src_unpack() {
	xpi_unpack "${P}"-fx+fl+zm+tb.xpi
}

src_install() {
	use firefox && declare MOZILLA_FIVE_HOME="/usr/$(get_libdir)/mozilla-firefox" && declare INSTALL_FOR="firefox" && xpi_install "${S}"/"${P}-fx+fl+zm+tb"
	use seamonkey && declare MOZILLA_FIVE_HOME="/usr/$(get_libdir)/seamonkey" && declare INSTALL_FOR="seamonkey" && xpi_install "${S}"/"${P}-fx+fl+zm+tb"
}