spamassassin-fuzzyocr-3.5.0_rc1.ebuild

spamassassin-fuzzyocr-3.5.0_rc1.ebuild (text/plain), 1.89 KB, created by Jacob Lindberg on 2006-12-18 03:55:21 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit perl-module

MY_P="fuzzyocr-${PV/_/-}"
DESCRIPTION="SpamAssassin plugin for performing Optical Character Recognition (OCR) on attached images"
HOMEPAGE="http://fuzzyocr.own-hero.net/"
SRC_URI="http://users.own-hero.net/~decoder/fuzzyocr/${MY_P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE=""
DEPEND="dev-lang/perl
	>=mail-filter/spamassassin-3.0.0"
RDEPEND="${DEPEND}
	media-libs/netpbm
	media-gfx/imagemagick
	media-libs/giflib
	app-text/gocr
	dev-perl/String-Approx
	virtual/perl-Digest-MD5
	dev-perl/MLDBM-Sync"

S="${WORKDIR}/FuzzyOcr-${PV/_/-}"

# Patch the package as recommended on the website / jni
src_unpack() {
	unpack ${A}
	cd ${S}
	epatch "${FILESDIR}"/patchset2.patch
}

src_install() {
	# called to get ${VENDOR_LIB}
	perlinfo

	local plugin_dir=${VENDOR_LIB}/Mail/SpamAssassin/Plugin

	insinto ${plugin_dir}
	doins FuzzyOcr.pm

	insinto /etc/mail/spamassassin/

	# Replace location of .pm file in config
	sed -ie "s:FuzzyOcr.pm:${plugin_dir}/FuzzyOcr.pm:" FuzzyOcr.cf

	# disable logging
	sed -ie "s:^#focr_verbose 1:focr_verbose 0.0:" FuzzyOcr.cf

	# if we're using spamassassin < 3.1.4 we need to set this variable
	if has_version '<mail-filter/spamassassin-3.1.4'; then
		sed -ie "s:^#focr_pre314 0.0:focr_pre314 1:" FuzzyOcr.cf
	fi

	doins FuzzyOcr.cf
	doins FuzzyOcr.words
	doins FuzzyOcr.scansets
	doins FuzzyOcr.preps
	insinto /etc/mail/spamassassin/FuzzyOcr
	doins FuzzyOcr/*

	docinto samples
	dodoc samples/*
}


pkg_postinst() {
	einfo "You need to restart spamassassin (as root) before this plugin will work:"
	einfo "/etc/init.d/spamd restart"
	echo
	ewarn "To avoid segfaulting and heavy loading from app-text/gocr, be sure to run at least"
	ewarn "0.43"
	echo
	einfo "$ emerge \">=app-text/gocr-0.43\""
	echo
	echo
}