soci-2.2.0.ebuild

soci-2.2.0.ebuild (text/plain), 1.19 KB, created by Zak Kipling on 2006-12-07 09:48:29 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="C++ Database Access Library"
HOMEPAGE="http://${PN}.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="Boost-1.0"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="firebird mysql oracle postgres sqlite3"

RDEPEND="firebird? ( >=dev-db/firebird-1.5.0 )
	mysql? ( >=dev-db/mysql-3.0.0 )
	oracle? ( >=dev-db/oracle-instantclient-basic-9.0 )
	postgres? ( >=dev-db/postgresql-7.1.4 )
	sqlite3? ( =dev-db/sqlite-3* )"
DEPEND="${RDEPEND}
	sys-devel/libtool"

src_compile() {
	econf \
		$(use_enable firebird backend-firebird) \
		$(use_enable mysql backend-mysql) \
		$(use_enable oracle backend-oracle) \
		$(use_enable postgres backend-postgresql) \
		$(use_enable sqlite3 backend-sqlite3) \
		|| die "configure failed"
	emake || die "make failed"
}

src_install() {
	emake install DESTDIR=${D} || die "install failed"
	dodoc README CHANGES doc/*.html doc/*.css doc/*.png doc/backends/*.html
}

src_test() {
	cd ${S}/src/backends
	
	# TODO: Test real backends; this requires access to a database server
	empty/test/test_empty "dummy_connection_string" || die "test_empty failed"
}