dev-python/myghty-1.1.ebuild

myghty-1.1.ebuild (text/plain), 1.41 KB, created by brad walker on 2006-11-16 11:12:05 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils

MY_PN="Myghty"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="View/Controller Framework and Templating Engine"
HOMEPAGE="http://www.myghty.org"
SRC_URI="http://cheeseshop.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="test"

RDEPEND=">=dev-lang/python-2.3.3
         >=dev-python/routes-1.0
         dev-python/paste
         dev-python/pastedeploy
         dev-python/pastescript"

DEPEND=">=dev-python/setuptools-0.6_rc1"

PYTHON_MODNAME=$MY_PN
S="${WORKDIR}/${MY_P}"

src_compile() {
	distutils_src_compile
	# generate the docs
	cd doc && python genhtml.py
}

src_install() {
	DOCS="CHANGES"
	distutils_src_install

	# Docs & examples
	dohtml -r doc/html
	insinto /usr/share/doc/${PF}
	doins -r examples

	# Tools & Tests
	insinto /usr/lib/${PF}
	doins -r tools/
	doins -r test/

	# Symlink tools/gen.py into the PATH
	dodir /usr/bin
	fperms 0755 /usr/lib/${PF}/tools/gen.py
	dosym /usr/lib/${PF}/tools/gen.py /usr/bin/myghty-gen
}

# fails perf_test_container.py
src_test() {
	for test in test/*.py
	do
		case "${test}" in
			# Skip the WSGI test as it's interactive, and has
			# dependencies that can't be fulfilled in Portage
			# yet.
			test/WSGI.py) continue ;;
		esac
		python "${test}" || die "ERROR: test ${test} failed!"
	done
}