ufo-ai-9999.ebuild

ufo-ai-9999.ebuild (text/plain), 2.76 KB, created by Paul Bredbury on 2006-11-15 18:29:53 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic toolchain-funcs subversion games

DESCRIPTION="UFO: Alien Invasion - X-COM inspired strategy game"
HOMEPAGE="http://www.ufoai.net/"
SRC_URI=""

# Good info: http://ufo.myexp.de/phpBB2/viewtopic.php?t=17
ESVN_REPO_URI="https://svn.sourceforge.net/svnroot/ufoai/ufoai/trunk"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="alsa arts debug dga ipv6 mmx nls oss paranoid"

# Info at http://ufo.myexp.de/wiki/index.php/Compile_for_Linux
# and http://ufo.myexp.de/wiki/index.php/Debian
RDEPEND=">=media-libs/libsdl-1.2
	>=media-libs/sdl-ttf-2
	virtual/opengl
	virtual/glu
	media-libs/jpeg
	media-libs/libvorbis
	media-libs/libogg
	nls? ( sys-devel/gettext )
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm"
# ca-certificates is needed for the svn connection to SourceForge
DEPEND="${RDEPEND}
	>=app-misc/ca-certificates-20050804
	app-arch/unzip
	x11-proto/xextproto"

S=${WORKDIR}
dir=${GAMES_DATADIR}/${PN}
libdir=${GAMES_LIBDIR}/${PN}

src_unpack() {
	einfo "If a subversion certificate error is shown, abort and then run:"
	einfo "   update-ca-certificates"
	echo
	subversion_src_unpack

	cd "${S}"

	# Find ufo2map executable, for compiling maps
	sed -i \
		-e "s:ufo2map:${S}/src/release/ufo2map:" \
		base/maps/Makefile || die "sed base/maps/Makefile failed"

	# Use shared directories
	sed -i \
		-e "s:\"basedir\", \".\":\"basedir\", \"${dir}\":" \
		-e "s:FS_AddGameDirectory(va(\"\%s/\" BASEDIRNAME, fs_basedir->string));:FS_AddGameDirectory(va(\"%s/\" BASEDIRNAME, fs_basedir->string));\n\tFS_AddGameDirectory(\"${libdir}\");:" \
		-e "s:FS_AddGameDirectory(va(\"\%s/\%s\", fs_basedir->string, dir));:FS_AddGameDirectory(va(\"\%s/\%s\", fs_basedir->string, dir));\n\tFS_AddGameDirectory(\"${libdir}\");:" \
		src/qcommon/files.c || die "sed files.c failed"
}

src_compile() {
	yesno() { useq $1 && echo YES || echo NO ; }

	local target="release"
	use debug && target="debug"

	cd src
	emake \
		BUILD_ALSA=$(yesno alsa) \
		BUILD_OSS=$(yesno oss) \
		BUILD_ARTS=$(yesno arts) \
		HAVE_IPV6=$(yesno ipv6) \
		HAVE_GETTEXT=$(yesno nls) \
		BUILD_WITH_DGA=$(yesno dga) \
		BUILD_WITH_VIDMODE=$(yesno X) \
		BUILD_WITH_MMX=$(yesno mmx) \
		BUILD_PARANOID=$(yesno paranoid) \
		CC="$(tc-getCC)" \
		BUILD_RELEASE_DIR=release \
		BUILD_DEBUG_DIR=release \
		build_${target} || die "emake ${target} failed"
	cd ..

	einfo "Compiling maps - this will take hours..."
	emake maps || die "emake maps failed"
}

src_install() {
	newgamesbin src/release/ufo ${PN} || die "newgamesbin ufo failed"

	exeinto "${libdir}"
	doexe src/release/game.so || die "doexe game.so failed"

	insinto "${dir}"
	doins -r base || die "doins base failed"

	dodoc AUTHORS CONTRIBUTORS README

	prepgamesdirs
}