[patch] ucspi-tcp-0.88-r17.ebuild

ucspi-tcp-0.88-r17.ebuild (text/plain), 3.12 KB, created by Manuel Mausz on 2006-11-14 14:54:25 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/ucspi-tcp/ucspi-tcp-0.88-r15.ebuild,v 1.2 2006/06/07 11:19:57 vapier Exp $

inherit eutils toolchain-funcs fixheadtails flag-o-matic

IPV6_PATCH="diff17"

DESCRIPTION="Collection of tools for managing UNIX services"
HOMEPAGE="http://cr.yp.to/ucspi-tcp.html"
SRC_URI="
	http://cr.yp.to/${PN}/${P}.tar.gz
	ipv6? ( http://www.fefe.de/ucspi/ucspi-tcp-0.88-ipv6.${IPV6_PATCH}.bz2 )
	mirror://qmail/ucspi-rss.diff
	ssl? (
		!ipv6? (
			http://manuel.mausz.at/programming/patches/ucspi-tcp/ucspi-tcp-ssl-20050405-mm.patch
		)
		ipv6? (
			http://manuel.mausz.at/programming/patches/ucspi-tcp/ucspi-tcp-ipv6-ssl-20050405-mm.patch
		)
	)
	limits? (
		http://manuel.mausz.at/programming/patches/ucspi-tcp/tcpserver-limits-2006-01-26-mm2.patch
		ipv6? (
			http://manuel.mausz.at/programming/patches/ucspi-tcp/tcpserver-limits-2006-01-26-ipv6.patch
		)
	)"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc-macos ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="ssl ipv6 limits selinux doc"
RESTRICT="test"

DEPEND="virtual/libc
	ssl? ( >=dev-libs/openssl-0.9.6g )"
RDEPEND="${DEPEND}
	doc? ( app-doc/ucspi-tcp-man )
	selinux? ( sec-policy/selinux-ucspi-tcp )"
PROVIDE="virtual/inetd"

src_unpack() {
	unpack ${P}.tar.gz
	cd "${S}"

	if use ipv6 ; then
		epatch "${DISTDIR}"/ucspi-tcp-0.88-ipv6.${IPV6_PATCH}.bz2
		# Fixes bug 18892
		epatch "${FILESDIR}"/${PV}-bigendian.patch
		epatch "${FILESDIR}"/${PV}-tcprules.patch
	fi

	if use ssl ; then
		if use ipv6 ; then
			epatch "${DISTDIR}"/ucspi-tcp-ipv6-ssl-20050405-mm.patch
		else
			epatch "${DISTDIR}"/ucspi-tcp-ssl-20050405-mm.patch
		fi
	fi

	if use !ssl && use !ipv6 ; then
		epatch "${FILESDIR}"/${PV}-errno.patch
	fi

	epatch "${DISTDIR}"/ucspi-rss.diff
	epatch "${FILESDIR}"/${PV}-rblsmtpd-ignore-on-RELAYCLIENT.patch

	if use limits ; then
		epatch "${DISTDIR}"/tcpserver-limits-2006-01-26-mm2.patch
		use ipv6 && epatch "${DISTDIR}"/tcpserver-limits-2006-01-26-ipv6.patch
	fi

	ht_fix_file Makefile

	# gcc-3.4.5 and other several versions contain a bug on some platforms that
	# cause this error:
	# tcpserver: fatal: temporarily unable to figure out IP address for 0.0.0.0: file does not exist
	# To work around this, we use -O1 here instead.
	replace-flags -O? -O1
	echo "$(tc-getCC) ${CFLAGS}" > conf-cc
	echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
	echo "/usr/" > conf-home

	# allow larger responses
	sed -i 's|if (text.len > 200) text.len = 200;|if (text.len > 500) text.len = 500;|g' ${S}/rblsmtpd.c
}

src_compile() {
	emake || die
}

src_install() {
	dobin tcpserver tcprules tcprulescheck argv0 recordio tcpclient *\@ \
		tcpcat mconnect mconnect-io addcr delcr fixcrio rblsmtpd || die
	doman *.[15]
	dodoc CHANGES FILES README SYSDEPS TARGETS TODO VERSION
	dodoc README.tcpserver-limits-patch
	insinto /etc/tcprules.d/
	newins "${FILESDIR}"/tcprules-Makefile Makefile
}

pkg_postinst() {
	einfo "We have started a move to get all tcprules files into"
	einfo "/etc/tcprules.d/, where we have provided a Makefile to"
	einfo "easily update the CDB file."
}