dev-python/hachoir-parser/hachoir-parser-0.6.1.ebuild

hachoir-parser-0.6.1.ebuild (text/plain), 2.41 KB, created by TGL on 2006-11-12 02:00:55 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils

DESCRIPTION="Collection of binary files parsers for \"dev-python/hachoir\""
HOMEPAGE="http://hachoir.org/wiki/hachoir-parser"
TESTS_URL="http://hachoir.tuxfamily.org/testcase"
METADATA_PV="0.6.0"
SRC_URI="http://cheeseshop.python.org/packages/source/h/${PN}/${P}.tar.gz
	test? (
		http://cheeseshop.python.org/packages/source/h/hachoir-metadata/hachoir-metadata-${METADATA_PV}.tar.gz
		${TESTS_URL}/yellowdude.3ds
		${TESTS_URL}/logo-Kubuntu.png
		${TESTS_URL}/mbr_linux_and_ext
		${TESTS_URL}/KDE_Click.wav
		${TESTS_URL}/test.txt.gz
		${TESTS_URL}/flashmob.mkv
		${TESTS_URL}/10min.mkv
		${TESTS_URL}/CD_0008_5C48_1m53s.cda
		${TESTS_URL}/wormux_32x32_16c.ico
		${TESTS_URL}/audio_8khz_8bit_ulaw_4s39.au
		${TESTS_URL}/sheep_on_drugs.mp3
		${TESTS_URL}/pyc_example_1.5.2.pyc
		${TESTS_URL}/pyc_example_2.2.3.pyc
		${TESTS_URL}/pyc_example_2.5c1.pyc
		${TESTS_URL}/ftp-0.17-537.i586.rpm
		${TESTS_URL}/cross.xcf
		${TESTS_URL}/jpeg.exif.photoshop.jpg
		${TESTS_URL}/small_text.tar
		${TESTS_URL}/cacert_class3.der
		${TESTS_URL}/kde_haypo_corner.bmp
		${TESTS_URL}/png_331x90x8_truncated.png
		${TESTS_URL}/steganography.mp3
		${TESTS_URL}/smallville.s03e02.avi
		${TESTS_URL}/08lechat_hq_fr.mp3
	)"
# To update SRC_URI of test cases, try this:
# sed -n '/^files = (/,/^)/s|^ *(u"\([^"]\+\).*|\t\t${TESTS_URL}/\1|p' tests/run_testcase.py

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="test"

RDEPEND=">=dev-lang/python-2.4
	=dev-python/hachoir-0.6*"
DEPEND="${RDEPEND}"

DOCS="AUTHORS"
PYTHON_MODNAME="${PN//-/_}"

src_unpack() {
	unpack ${P}.tar.gz
	if use test ; then
		# Needed to run tests, but can't be in DEPEND (circular dep):
		unpack hachoir-metadata-${METADATA_PV}.tar.gz
		sed -i "/^metadir *=/{N;c\
				sys.path[:0] = [\"${S}\",\"${WORKDIR}/hachoir-metadata-${METADATA_PV}\"]
			}"  "${S}/tests/run_testcase.py"
		# Puts the test cases at the right place, or they would be downloaded:
		mkdir -p "${S}/tests/testcase"
		local testcase
		for testcase in ${A} ; do
			ln -s "${DISTDIR}/${testcase}" "${S}/tests/testcase"
		done
	fi
}

src_test() {
	if use test ; then
		./tests/run_testcase.py || die "Failed to run tests"
	else
		ewarn "Skipping tests since they would have downloaded some files."
		ewarn "If you want to run them next time, set the \"test\" USE flag."
		# Should it die instead of ewarn?
	fi
}