quetoo-0.5.1.ebuild

quetoo-0.5.0.ebuild (text/plain), 1.23 KB, created by Paul Bredbury on 2006-11-06 14:08:25 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils games

DESCRIPTION="Quake 2 performance engine"
HOMEPAGE="http://jdolan.dyndns.org/jaydolan/quetoo.html"
SRC_URI="http://jdolan.dyndns.org/jaydolan/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="alsa mysql sdl"

RDEPEND="alsa? ( media-libs/alsa-lib )
	virtual/opengl
	sdl? ( media-libs/libsdl )
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXxf86vm"
DEPEND="${RDEPEND}
	x11-proto/xf86vidmodeproto
	x11-proto/xproto"

src_unpack() {
	unpack ${A}
	cd "${S}"

	eautoreconf
}

src_compile() {
	# It magically finds ${GAMES_DATADIR}/quake2
	egamesconf \
		$(use_with alsa) \
		$(use_with sdl) \
		$(use_with mysql) \
		--with-opengl \
		--with-x \
		--enable-qmass \
		|| die "egamesconf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	make_desktop_entry ${PN} "Quetoo"

	dodoc README

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Be warned, there is no user interface in this game."
	elog "To start a map, type e.g.:  map base1"
	elog "The configuration is saved in ~/.quake2/baseq2/quetoo.cfg"
	echo
}