quake1-undergate-1.2.2.ebuild

quake1-undergate-1.2.2.ebuild (text/plain), 1.28 KB, created by Paul Bredbury on 2006-10-19 11:56:36 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

MY_PN=${PN#quake1-}
MY_PV=$(get_version_component_range 1-1)-$(get_version_component_range 2-2)-r$(get_version_component_range 3-3)

DESCRIPTION="Collection of 104 single-player Quake 1 maps with an intro map"
HOMEPAGE="http://www.quakeone.com/index.php?ind=downloads&op=view_file&file_id=164"
SRC_URI="${MY_PN}-${MY_PV}.7z"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE="darkplaces joequake"
RESTRICT="fetch strip"

# quake1-demodata is not sufficient
RDEPEND="games-fps/quake1-data
	darkplaces? ( games-fps/darkplaces )"
DEPEND="app-arch/p7zip"

S=${WORKDIR}

pkg_nofetch() {
	einfo "Please download ${A} from:"
	einfo "${DOWNLOAD_URL}"
	einfo "and move it to ${DISTDIR}"
}

src_unpack() {
	unpack ${A}

	rm *.exe fitz*.txt readmegl.txt
}

src_install() {
	insinto "${GAMES_DATADIR}"/quake1
	doins -r * || die "doins -r failed"

	local e
	for e in darkplaces joequake ; do
		if use ${e} ; then
			games_make_wrapper ${e}-${MY_PN} \
				"${e} -game ${MY_PN} +map ${MY_PN}"
			local title="Dark Places"
			[[ "${e}" = "joequake" ]] && title="JoeQuake"
			make_desktop_entry ${e}-${MY_PN} \
				"${title} - Undergate" ${e}.png
		fi
	done

	prepgamesdirs
}