# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils fixheadtails multilib toolchain-funcs

MY_PN=Producer
OSG_V=1.2
DESCRIPTION="Cross-platform OpenGL Library, focused on camera control"
HOMEPAGE="http://www.openscenegraph.org/"
SRC_URI="http://www.openscenegraph.org/downloads/snapshots/OSG_OP_OT-${OSG_V}.zip"

SLOT="0"
LICENSE="OSGPL"
KEYWORDS="x86"
IUSE="doc examples"

RDEPEND="virtual/opengl
		>=dev-libs/openthreads-1.5.0"

DEPEND="${RDEPEND}
		app-arch/unzip
		doc? ( app-doc/doxygen )"

S=${WORKDIR}/OSG_OP_OT-${OSG_V}/${MY_PN}

src_unpack() {
	unpack ${A}
	cd "${S}"
	
	epatch "${FILESDIR}"/${P}-build.patch

	ht_fix_all
}

src_compile() {
	emake CXX=$(tc-getCXX) || die "emake failed"

	if use doc ; then
		doxygen -u doc/doxy.cfg
		doxygen doc/doxy.cfg
	fi
}

src_install() {
	make INST_LOCATION="${D}"/usr install || die "make install failed"

	dosym /usr/$(get_libdir)/lib${MY_PN}.so{.${PV%%.*},} || die "dosym failed"

	insinto /usr/$(get_libdir)/pkgconfig
	doins Make/producer.pc

	use doc && dohtml -r doc/Doxygen/html/*

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins -r doc/Tutorial/SourceCode/*
	fi

	dodoc README.txt
}