freecol-0.5.0.ebuild

freecol-0.5.0.ebuild (text/plain), 913 bytes, created by Tristan Heaven (RETIRED) on 2006-09-19 15:33:47 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-ant-2 java-pkg-2 games

DESCRIPTION="An open source clone of the game Colonization"
HOMEPAGE="http://www.freecol.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE=""

RDEPEND=">=virtual/jre-1.4"
DEPEND=">=virtual/jdk-1.4
	dev-java/ant"

S=${WORKDIR}/${PN}

pkg_setup() {
	games_pkg_setup
	java-pkg-2_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e '/saveDirectory/s/freecol/.freecol/' \
		src/net/sf/freecol/FreeCol.java \
		|| die "sed failed"
}

src_compile() {
	eant
}

src_install() {
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r FreeCol.jar data jars || die "doins failed"

	games_make_wrapper ${PN} "java -Xmx128M -jar FreeCol.jar" \
		"${GAMES_DATADIR}"/${PN}

	dodoc README
	prepgamesdirs
}