warsow-0.20.ebuild

warsow-0.20.ebuild (text/plain), 4.41 KB, created by Johannes Athmer on 2006-09-16 05:52:16 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

# Warsow uses a different (decimal?) versioning system:
# 0.1 < 0.11 < 0.12 < 0.2
# However, the ebuild has to be named 0.20 so that gentoo sees 0.2 (0.20) > 0.12
MY_PV=0.2
S_PV=${MY_PV/./}
F=${PN}_${MY_PV}_linux.tar.gz
SDK=${PN}_${MY_PV}_sdk.zip

DESCRIPTION="Multiplayer FPS based on the QFusion engine (evolved from Quake 2)"
HOMEPAGE="http://www.warsow.net/"
SRC_URI="ftp://ftp.club-internet.fr/pub/games/nofrag/${PN}/${F}
	ftp://ftp.club-internet.fr/pub/games/nofrag/${PN}/${SDK}
	http://www.bef-warsow.de/files/${F}
	http://www.bef-warsow.de/files/${SDK}
	http://wsw.surreal-xenotronic.com/${F}
	http://wsw.surreal-xenotronic.com/${SDK}
	http://ik.spinther.com/${PN}/${F}
	http://ik.spinther.com/${PN}/${SDK}
	http://warsow.routed-gaming.co.uk/downloads/${F}
	http://warsow.routed-gaming.co.uk/downloads/${SDK}
	http://warsownews.game-server.cc/${F}
	http://warsownews.game-server.cc/${SDK}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated sdl openal irc"

UIRDEPEND="media-libs/jpeg
	net-misc/curl
	virtual/opengl
	|| ( (
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
UIDEPEND="|| ( (
			x11-proto/xf86dgaproto
			x11-proto/xf86vidmodeproto )
		virtual/x11 )"
SDLDEPEND=">=media-libs/libsdl-1.2.8-r1
	>=media-libs/sdl-sound-1.0.1-r1"
OALDEPEND="media-libs/openal"
RDEPEND="sdl? ( ${SDLDEPEND} ${UIRDEPEND} )
	openal? ( ${OALDEPEND} ${UIRDEPEND} )
	!sdl? ( !openal? ( !dedicated? ( ${UIRDEPEND} ) ) )"
DEPEND="${RDEPEND}
	sdl? ( ${UIDEPEND} )
	openagl? ( ${UIDEPEND} )
	!sdl? ( !openal? ( !dedicated? ( ${UIDEPEND} ) ) )
	!games-fps/warsow-bin
	app-arch/unzip"

S=${WORKDIR}/source
SDATA=${WORKDIR}/${PN}
dir=${GAMES_DATADIR}/${PN}
libdir=${GAMES_LIBDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Make fs_usehomedir default to 1, so the game will write to ~/.warsow/
	# Make fs_basepath default to correct path.
	# Add libdir as game directory.
	sed -i qcommon/files.c \
		-e 's:"fs_usehomedir", "0":"fs_usehomedir", "1":' \
		-e "s:\"fs_basepath\", \"\.\":\"fs_basepath\", \"${dir}\":" \
		|| die "sed files.c failed"

	# Remove pre-compiled binaries, because they are compiled in src_compile()
	# Also remove the start scripts, we don't need them.
	rm "${SDATA}"/{${PN}*,wsw_server*}

	# Remove pre-compiled libraries, because they are compiled in src_compile()
	rm -r "${SDATA}"/libs/*.so

	# Remove copy of licence.
	rm "${SDATA}"/docs/gnu.txt

	# Move docs to a convenient directory, away from the files to be installed.
	mv "${SDATA}"/docs "${S}"
}

src_compile() {
	local makeopts="game"

	if use sdl ; then
		# Compile sdl/qf sound module.
		makeopts="${makeopts} qf"
	fi
	if use openal ; then
		# Compile OpenAL sound module.
		makeopts="${makeopts} openal"
	fi
	if use sdl || use openal || ! use dedicated ; then
		# Compile client.
		makeopts="${makeopts} client cgame ui"
	fi
	if use dedicated ; then
		# Compile server.
		makeopts="${makeopts} ded"
	fi
	if use irc ; then
		# Compile IRC client.
		makeopts="${makeopts} irc"
	fi

	emake \
		BINDIR=release \
		SERVER_EXE=wsw_server \
		CLIENT_EXE=${PN} \
		${makeopts} \
		|| die "emake failed"

	mv release/basewsw/*.so "${WORKDIR}"
	cp -rf release/basewsw "${SDATA}" || die "cp basewsw failed"
}

src_install() {
	cd "${SDATA}"

	if use sdl || use openal || ! use dedicated ; then
		# Install client-only components.
		dogamesbin "${S}/release/${PN}" \
			|| die "dogamesbin ${PN} failed"
		make_desktop_entry ${PN} "Warsow"
	fi

	if use dedicated ; then
		# Install server-only components.
		dogamesbin "${S}/release/wsw_server" \
			|| die "dogamesbin wsw_server failed"
	fi

	# Install common components.
	insinto "${dir}"
	doins -r * || die "doins -r failed"

	# Game libraries.
	exeinto "${libdir}"/basewsw
	local lib
	for lib in $(cd "${WORKDIR}" && ls -A *.so) ; do
		doexe "${WORKDIR}/${lib}" || die "doexe ${lib} failed"
		dosym "${libdir}/basewsw/${lib}" "${dir}"/basewsw/
	done

	# "Shared" Libraries.
	exeinto "${libdir}"
	local lib2
	for lib2 in $(cd "${S}"/release/libs/ && ls -A *.so) ; do
		doexe "${S}"/release/libs/"${lib2}" || die "doexe ${lib2} failed"
		dosym "${libdir}/${lib2}" "${dir}"/libs/
	done

	dodoc "${S}"/docs/*

	prepgamesdirs
}