# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit mono eutils fdo-mime

DESCRIPTION="Free .NET development environment"
HOMEPAGE="http://monodevelop.com/"
SRC_URI="http://www.go-mono.com/sources/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="boo debugger java nemerle asp vte"

DEPEND=">=dev-dotnet/gtk-sharp-2.4.2
	>=dev-dotnet/gtksourceview-sharp-0.10
	>=dev-dotnet/gnome-sharp-2.4.0
	>=dev-dotnet/glade-sharp-2.4.0
	>=dev-dotnet/gconf-sharp-2.4.0
	>=dev-dotnet/gecko-sharp-0.10
	>=dev-lang/mono-1.1.10
	>=dev-util/monodoc-1.0
	>=dev-dotnet/gtkhtml-sharp-2.4.0
	>=dev-dotnet/gnomevfs-sharp-2.4.0
	vte? ( >=dev-dotnet/vte-sharp-2.4.0 )
	debugger? ( >=dev-dotnet/monodebugger-0.9 )
	asp? ( dev-dotnet/xsp )
	nemerle? ( >=dev-lang/nemerle-0.9.3 )
	boo? ( >=dev-lang/boo-0.7.5 )
	java? ( || ( >=dev-dotnet/ikvm-bin-0.14 >=dev-dotnet/ikvm-0.14.0.1-r1 ) )"
RDEPEND="${DEPEND}"

src_compile() {

	# ATTENTION: monodevelop do not compile with 'make -j2' or more
	# parallel job, so we need to filter it to -j1
	conf="$(use_enable boo) \
		$(use_enable java) \
		$(use_enable nemerle) \
		--enable-nunit \
		--enable-versioncontrol \
		--disable-update-mimedb \
		--disable-update-desktopdb "

	# enable Mono Debugger
	if use debugger; then
	    echo
    	ewarn 'The USE="debugger" flag install Mono Debugger (dev-dotnet/monodebugger),'
	    ewarn 'but the software is subject to API changes soften because is still a relative'
    	ewarn 'young project, so can happen that the configure process fail due an:'
    	echo
    	ewarn '-The debugger add-in is not currently supported due to the API changes being done in the Mono debugger-'
    	echo
    	ewarn 'Unfortunately there is not a real solution to the problem, until the mono devels will stop'
    	ewarn 'the API changes and made an official release.'
    	ewarn 'As a temporarely workaround set USE="-debugger"'
	    echo
        ebeep 5
		conf="${conf} $(use_enable debugger)"
	fi

	# enable ASP.NET Project and Visual Designer
	if use asp; then
		ewarn "ASP.NET Visual Designer is still in an early stage of development,"
		ewarn "so for this MonoDevelop version is temporarely disabled"
		ewarn "until a proper release will be available to the end users."
		einfo "For more infos go here: http://www.mono-project.com/AspNetEdit"
		echo
		ebeep 3
		conf="${conf} --enable-aspnet"
		#conf="${conf} --enable-aspnet --enable-aspnetedit"
	fi

	econf ${conf} || die "configure failed"
	emake -j1 || die "make failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc ChangeLog README
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}