sdlmame-0.108_p3.ebuild

sdlmame-0.108_p3.ebuild (text/plain), 2.24 KB, created by Paul Bredbury on 2006-09-10 15:06:15 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic toolchain-funcs eutils games

MY_PV=${PV/./}
MY_PV=${MY_PV/_p/u}
MY_P=${PN}${MY_PV}

DESCRIPTION="Multiple Arcade Machine Emulator for SDL"
HOMEPAGE="http://rbelmont.mameworld.info/"
SRC_URI="http://rbelmont.mameworld.info/${MY_P}.zip"

LICENSE="MAME"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="custom-cflags dynarec pbuffers"
# Needs fetch restriction due to $HOMEPAGE blocking wget downloads
# Binaries are already stripped
RESTRICT="fetch strip"

RDEPEND="dev-libs/expat
	sys-libs/zlib
	>=media-libs/libsdl-1.2.11
	virtual/opengl
	virtual/glu
	|| ( (
			x11-libs/libXext
			x11-libs/libXau
			x11-libs/libXdmcp )
		virtual/x11 )"
DEPEND="${RDEPEND}
	x11-proto/xproto
	app-arch/unzip"

S=${WORKDIR}/${MY_P}

enable_feature() {
	if use $1 ; then
		sed -i \
			-e "/$2.*=/s:#::" \
			makefile || die "sed makefile ($1 / $2) failed"
	fi
}

pkg_nofetch() {
	einfo "Please download ${SRC_URI}"
	einfo "and move it to ${DISTDIR}"
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Turn debug off, to allow it to compile
	sed -i \
		-e "s:DEBUG = 1:#DEBUG = 1:" \
		-e "/PM.*=/s:^:# :" \
		-e "/MIPS3_DRC.*= 1/s:^:# :" \
		-e "/PPC_DRC.*= 1/s:^:# :" \
		makefile || die "sed makefile failed"

	if use custom-cflags ; then
		sed -i \
			-e "s:-Wdeclaration-after-statement:-Wdeclaration-after-statement ${CFLAGS}:" \
			-e "s:LDFLAGS = -WO:LDFLAGS = ${LDFLAGS}:" \
			makefile || die "sed makefile custom-cflags failed"
	fi

	enable_feature amd64 AMD64
	enable_feature amd64 PTR64
	enable_feature ppc64 PTR64

	case $(get-flag march) in
		pentium3)	enable_feature x86 PM;;
		pentium4)   enable_feature x86 P4;;
		athlon*)	enable_feature x86 ATHLON;;
		k7)			enable_feature x86 ATHLON;;
		g4)			enable_feature x86 G4;;
		g5)			enable_feature x86 G5;;
		i686)		enable_feature x86 I686;;
		pentiumpro)	enable_feature x86 I686;;
	esac

	enable_feature pbuffers OGL_PIXELBUFS
	use x86 && enable_feature dynarec X86_MIPS3_DRC
	use x86 && enable_feature dynarec X86_PPC_DRC

	# Does not compile
	# use x86 && enable_feature dynarec X86_VOODOO_DRC
}

src_install() {
	dogamesbin mame* || die "dogamesbin failed"

	dodoc docs/* SDLMAME.txt whatsnew*

	prepgamesdirs
}