# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="free alternative to popular programs such as FruityLoops, Cubase and Logic"
HOMEPAGE="http://lmms.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
		vst? ( vst_sdk2_3.zip )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug flac jack ladspa oss samplerate sdl vorbis vst"
RESTRICT="fetch strip"

DEPEND="=x11-libs/qt-3.3*
	vorbis? ( media-libs/libvorbis )
	alsa? ( media-libs/alsa-lib )
	sdl? ( media-libs/libsdl
		>=media-libs/sdl-sound-1.0.1 )
	samplerate? ( media-libs/libsamplerate )
	jack? ( >=media-sound/jack-audio-connection-kit-0.99.0 )
	flac? ( media-libs/flac )
	ladspa? ( media-libs/ladspa-sdk )
	vst? ( app-emulation/wine
		app-arch/unzip )"

RDEPEND="${DEPEND}"

pkg_nofetch() {
	einfo "In order to use VST plugins you need to download the VST SDK 2.3"
	einfo "Download it from http://www.steinberg.de/331+M52087573ab0.html"
	einfo "and put it on /usr/portage/distfiles"
	einfo "You also can disable de vst USE flag"
}

src_unpack() {
	unpack ${A}
	if use vst ; then
		cd ${WORKDIR}
		unzip ${WORKDIR}/vstsdk2.3.zip
		cp ${WORKDIR}/vstsdk2.3/source/common/{AEffect.h,aeffectx.h} ${WORKDIR}/${P}/include/
	fi
}


src_compile() {
	econf \
		$(use_with alsa asound) \
		$(use_with flac) \
		$(use_with ladspa) \
		$(use_with vorbis) \
		$(use_with samplerate libsrc) \
		$(use_with oss) \
		$(use_with sdl) \
		$(use_with sdl sdlsound) \
		$(use_with jack) \
		$(use_with vst) \
		$(use_with debug) \
		--enable-hqsinc || die "econf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	newicon usr/share/lmms/themes/default/icon.png ${PN}.png
	make_desktop_entry ${PN} "Linux Multimedia Studio" ${PN}.png "Qt;Audio;AudioVideoEditing"
	dodoc README AUTHORS ChangeLog TODO
}