# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Freedoom - open-source replacement Doom resources"
HOMEPAGE="http://freedoom.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-demo-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-iwad-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-graphics-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-levels-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-resource-wad-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-sounds-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-sprites-${PV}.zip
	mirror://sourceforge/${PN}/${PN}-textures-${PV}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND=""
DEPEND="app-arch/unzip"

S=${WORKDIR}

src_install() {
	insinto "${GAMES_DATADIR}/doom-data/${PN}"
	doins */*.wad || die "doins wad failed"
	dodoc ${PN}-resource-wad-${PV}/{CREDITS,ChangeLog,NEWS,README}

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "A Doom engine is required to play the wads. It is recommended to"
	elog "emerge games-fps/doomsday with its 'freedoom' USE flag."
	echo
	ewarn "To play freedoom with Doom engines which do not support"
	ewarn "subdirectories, create symlinks by running the following:"
	ewarn "(Be careful of overwriting existing wads.)"
	ewarn
	ewarn "   cd ${ROOT}${GAMES_DATADIR}/doom-data"
	ewarn '   for f in doom{1,2} freedoom{,_graphics,_levels,_sounds,_sprites,_textures} ; do'
	ewarn '       ln -sn freedoom/${f}.wad'
	ewarn "   done"
	echo
}