winetools-0.9.ebuild

winetools-0.9.ebuild (text/plain), 1.58 KB, created by Paul Bredbury on 2006-09-02 18:29:28 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P=${P}jo-III

DESCRIPTION="Graphical Wine tool for installing Windows programs under Wine"
HOMEPAGE="http://www.von-thadden.de/Joachim/WineTools/index.html"
SRC_URI="http://ds80-237-203-29.dedicated.hosteurope.de/wt/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

RDEPEND="app-emulation/wine
	nls? ( sys-devel/gettext )
	x11-misc/xdialog"
DEPEND=""

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e "s:\${BASEDIR}/doc:/usr/share/doc/${PF}:g" \
		-e "/^DIALOG=/s:=.*:=\$(which Xdialog):" \
		-e "s:/usr/local/${PN}:/usr/share/${PN}:g" \
		-e "s:/usr/local/share/locale:/usr/share/locale:g" \
		-e "/README/s:cat:zcat:" \
		findwine wt${PV}jo || die "sed"
}

src_install() {
	dodoc doc/README.* doc/*.txt
	dohtml doc/*.html doc/*.gif

	if use nls ; then
		local i
		for i in po/*.po ; do
			i=${i##*/}
			i=${i%.po}
			dodir /usr/share/locale/${i}/LC_MESSAGES
			msgfmt po/${i}.po -o \
				"${D}"/usr/share/locale/${i}/LC_MESSAGES/wt${PV}.mo \
				|| die "msgfmt ${i} failed"
		done
	fi

	exeinto /usr/share/${PN}
	doexe wt${PV}jo chopctrl.pl findwine listit || die "doexe"

	insinto /usr/share/${PN}
	doins -r *.reg gettext.sh.dummy icon scripts 3rdParty || die "doins"

	dodir /usr/bin
	dosym /usr/share/${PN}/findwine /usr/bin/findwine
	dosym /usr/share/${PN}/wt${PV}jo /usr/bin/wt
	dosym /usr/share/${PN}/wt${PV}jo /usr/bin/${PN}

	doicon icon/${PN}.png || die "doicon"
	make_desktop_entry ${PN} Winetools wine Emulation
}