nautilus-share-0.7.0.ebuild

nautilus-share-0.7.0.ebuild (text/plain), 3.10 KB, created by Gilles Dartiguelongue (RETIRED) on 2006-08-13 07:34:48 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnome2 eutils

DESCRIPTION="A nautilus plugin to easily share folders over the SMB protocol"
HOMEPAGE="http://gentoo.ovibes.net/nautilus-share"
SRC_URI="http://gentoo.ovibes.net/${PN}/${P}.tar.gz"
IUSE=""
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"

DEPEND=">=gnome-base/nautilus-2.10.0
	>=gnome-base/eel-2.10.0
	>=dev-libs/glib-2.4.0
	>=gnome-base/libglade-2.4.0
	>=dev-libs/libdaemon-0.7
	>=sys-apps/dbus-0.23"
RDEPEND="${DEPEND}
	>=x11-themes/gnome-icon-theme-2.10.1
	>=net-fs/samba-3.0.23a"

DOCS="AUTHORS BUGS INTERNAL README TODO"

G2CONF="--with-dbus-sys=/etc/dbus-1/system.d"

pkg_setup() {
	if ! built_with_use sys-apps/dbus gtk; then
		eerror "Need GLib support in DBUS."
		eerror "Please re-emerge sys-apps/dbus with gtk USE flag enabled."
		die "unmet dependencies"
	fi
}

src_install() {
	gnome2_src_install "$@"

	# debian only
	rm -r ${D}/etc/dbus-1/event.d
	doinitd ${FILESDIR}/smbshared
}

pkg_preinst() {	
	if ! [[ -e ${ROOT}/etc/samba/smb.conf ]]; then
		dodir /etc/samba
		cat > ${IMAGE}/etc/samba/smb.conf <<END

[global]
workgroup =  WORKGROUP
security = share

# user share
usershare path = /usr/local/samba/lib/usershares
usershare max shares = 100

# directive to enable gnome-extra/nautilus-share
include = /etc/samba/smbshared.conf

END
		fperms 644 /etc/samba/smb.conf
	fi
	if ! [[ -e ${ROOT}/etc/samba/smbshared.conf ]]; then
		dodir /etc/samba
		touch ${IMAGE}/etc/samba/smbshared.conf
		fperms 644 /etc/samba/smbshared.conf
	fi
}

pkg_postinst() {
	einfo "To get nautilus-share working:"
	echo
	if ! grep 'include[[:space:]]*=[[:space:]]*/etc/samba/smbshared.conf' \
		-q ${ROOT}/etc/samba/smb.conf; then
		elog "Add the lines"
		elog ""
		elog "    # user share"
		elog "    usershare path = /usr/local/samba/lib/usershares"
		elog "    usershare max shares = 100"
		elog ""
		elog "    # directive to enable gnome-extra/nautilus-share"
		elog "    include = /etc/samba/smbshared.conf"
		elog ""
		elog "to the end of the [global] section in /etc/samba/smb.conf"
		elog ""
	fi
	elog "Issue the following commands as root:"
	elog ""
	elog "  # mkdir /usr/local/samba/lib/usershares"
	elog "  # chown root:users /usr/local/samba/lib/usershares"
	elog "  # chmod 01770 /usr/local/samba/lib/usershares"
	elog ""
	elog "  # rc-update add smbshared default"
	elog "  # /etc/init.d/dbus restart"
	elog "  # /etc/init.d/smbshared start"
	elog ""
	elog "As your current user, restart nautilus:"
	elog ""
	elog "  $ nautilus -q"
	elog ""
}

pkg_postrm() {
	if ! has_version ${CATEGORY}/${PN}; then
		if [[ -e ${ROOT}/etc/samba/smb.conf ]] && \
			grep 'include[[:space:]]*=[[:space:]]*/etc/samba/smbshared.conf' \
			-q ${ROOT}/etc/samba/smb.conf
		then
			ebeep
			ewarn "SECURITY ADVISORY:"
			ewarn "You probably should remove the line"
			echo
			ewarn "    include = /etc/samba/smbshared.conf"
			echo
			ewarn "from /etc/samba/smb.conf"
			echo
		fi
		if [[ -e ${ROOT}/etc/samba/smbshared.conf ]]; then
			ebeep
			ewarn "SECURITY ADVISORY:"
			ewarn "You probably should delete /etc/samba/smbshared.conf"
			echo
		fi
	fi
}