# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator games

MY_PV=$(delete_all_version_separators)
MOD="dungeondoom"

DESCRIPTION="Rogue-like 3D mod for Doom 3"
HOMEPAGE="http://dungeondoom.d3files.com/"
SRC_URI="mirror://filefront/Doom_III/Hosted_Mods/Final_Releases/DungeonDOOM/${MOD}${MY_PV}xplinux.zip"

# See bottom of /opt/doom3/dungeondoom/readme.txt
LICENSE="as-is"

SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="strip"

RDEPEND="games-fps/doom3-roe
	!games-fps/doom3-ducttape"
DEPEND="app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/doom3

src_unpack() {
	unpack ${A}

	# Standardize directory name.
	local dir=$(find . -maxdepth 1 -name "dungeon*" -type d)
	mv "${dir}" "${MOD}" || die "mv ${dir} failed"
}

src_install() {
	insinto "${dir}"
	doins -r "${MOD}" || die "doins failed"

	# This non-standard command-line is required.
	games_make_wrapper ${PN} "doom3 +set fs_game ${MOD} +set fs_game_base d3xp"
	make_desktop_entry ${PN} "Doom III - Dungeon" doom3.png

	prepgamesdirs
}