# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/molden/molden-4.3.ebuild,v 1.10 2006/04/08 10:36:13 blubb Exp $

inherit eutils toolchain-funcs flag-o-matic fortran

MY_P="${PN}${PV}"
DESCRIPTION="Display molecular density from GAMESS-UK, GAMESS-US, GAUSSIAN and Mopac/Ampac."
HOMEPAGE="http://www.cmbi.kun.nl/~schaft/molden/molden.html"
SRC_URI="ftp://ftp.cmbi.kun.nl/pub/molgraph/${PN}/${MY_P}.tar.Z"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64"
IUSE="opengl"

RDEPEND="opengl? ( virtual/glut
		virtual/opengl )
	|| ( x11-libs/libXmu virtual/x11 )"
DEPEND="${RDEPEND}
	virtual/libc"

S=${WORKDIR}/${MY_P}


patch_fortran() {
	local PATCHES=$(find ${FILESDIR} -name "${P}-${FORTRANC}-*")
	
	einfo "Applying patches for selected FORTRAN compiler: ${FORTRANC}"
	
	local PATCH
	
	if [ -n "${PATCHES}" ]; then
		for PATCH in ${PATCHES}; do
			epatch ${PATCH}
		done
	fi
}

src_unpack() {
	need_fortran g77 gfortran
	fortran_src_unpack
	fortran_pkg_setup

}

src_compile() {

	# Use -mieee on alpha, according to the Makefile
	use alpha && append-flags -mieee

	# Honor CC, CFLAGS, FC, and FFLAGS from environment;
	# unfortunately a bash bug prevents us from doing typeset and
	# assignment on the same line.
	typeset -a args
	args=( CC="$(tc-getCC) ${CFLAGS}" \
		${FC:+FC="${FC}" LDR="${FC}"} \
		${FFLAGS:+FFLAGS="${FFLAGS}"} )

	einfo "Building Molden..."
	emake -j1 "${args[@]}" || die "molden emake failed"
	if use opengl ; then
		einfo "Building Molden OpenGL helper..."
		emake -j1 "${args[@]}" moldenogl || die "moldenogl emake failed"
	fi
}

src_install() {
	dobin molden
	use opengl && dobin moldenogl
	dodoc HISTORY README REGISTER
	cd doc
	uncompress *
	dodoc *
}