# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils games

DESCRIPTION="Biloba is a board game, up to 4 players, with AI and network."
HOMEPAGE="http://perso.wanadoo.fr/biloba/"
SRC_URI="mirror://sourceforge/biloba/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=media-libs/libsdl-1.2.4
	>=media-libs/sdl-image-1.2
	>=media-libs/sdl-mixer-1.2"

DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# "es" data were installed in /usr/games/share instead of /usr/share/games
	epatch "${FILESDIR}/${P}-fix-es-data-install-path.patch"

	# X11 headers are checked but not used, everything is done through SDL
	epatch "${FILESDIR}/${P}-no-X11-dep.patch"

	# no need to warn about a missing Windows tool ("windres")
	epatch "${FILESDIR}/${P}-not-windows.patch"

	# "missing" file is old, and warns about --run not being supported
	rm -f missing

	eautoreconf
}

src_install() {
	make DESTDIR=${D} install || die "Installation failed"
	prepgamesdir
	
	dodoc AUTHORS ChangeLog README
	newicon biloba_icon.png biloba.png
	make_desktop_entry biloba Biloba
}