dev-games/ogre-1.2.2_p1-r1.ebuild

ogre-1.2.2_p1-r1.ebuild (text/plain), 2.79 KB, created by Sergey Belyashov on 2006-07-28 09:33:04 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV=${PV//./-}
MY_PV=${MY_PV//_/}

DESCRIPTION="Object-oriented Graphics Rendering Engine"
HOMEPAGE="http://www.ogre3d.org/"
SRC_URI="mirror://sourceforge/ogre/${PN}-linux_osx-v${MY_PV}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="cegui cg debug devil doc double-precision examples openexr sdl threads"

RDEPEND=">=dev-libs/zziplib-0.13.36
	>=media-libs/freetype-2.1.10
	threads? ( >=dev-libs/boost-1.33.0 )
	cegui? ( >=dev-games/cegui-0.4.0 )
	devil?	( >=media-libs/devil-1.6.7 )
	openexr? ( >=media-libs/openexr-1.2 )
	sdl? ( >=media-libs/libsdl-1.2.8 )
	virtual/opengl
	sys-libs/zlib"

DEPEND="${RDEPEND}
	sys-devel/flex
	cg? ( >=media-gfx/nvidia-cg-toolkit-1.2 )"

S=${WORKDIR}/ogrenew
RESTRICT="debug? ( strip )"

pkg_setup() {
	if has_version dev-games/ogre ; then
		eerror "***************************************************************"
		eerror "* Before installing new version (or reinstall current one) of *"
		eerror "* dev-games/ogre You need to uninstall currently existing in  *"
		eerror '* system. Type "emerge -C dev-games/ogre" to do it now.       *'
		eerror "***************************************************************"
		die "ogre already installed"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	#epatch "${FILESDIR}"/${P}-gcc{34,41}.patch

	#if has_version ">=dev-games/cegui-0.4.1"
	#then 
	#  epatch "${FILESDIR}"/cegui-0.4.1.patch
	#fi
	epatch "${FILESDIR}"/ogre-1.2.1-deferredshading-double-precision.patch
	epatch "${FILESDIR}"/ogre-1.2.1-config-disable-samples.patch
	epatch "${FILESDIR}"/ogre-1.2.1-pkgconfig-double-precision.patch
	epatch "${FILESDIR}"/ogre-1.2.1-sdl-isfullscreen.patch

	einfo Running boostrap
	./bootstrap || die "bootstrap failed"
}

src_compile() {
	local mycfgtk="cli"

	local myplat="GLX"
	use sdl && myplat="SDL"

	econf \
		--with-cfgtk=${mycfgtk} \
		--with-platform=${myplat} \
		$(use_enable devil) \
		$(use_enable cg) \
		$(use_enable openexr) \
		$(use_enable threads threading) \
		$(use_enable double-precision double) \
		$(use_enable debug) \
		$(use_enable examples samples) \
		|| die
	emake || die "emake failed"
}

src_install() {
	#make DESTDIR="${D}" install || die "install failed"
	einstall || die "install failed"
	insinto /usr/share/OGRE/Media
	doins -r Samples/Media/*
	if use examples ; then
		into /usr/share/OGRE/Samples/
		dobin Samples/Common/bin/*
		insinto /usr/share/OGRE/Samples/bin/
		echo "" > Samples/Common/bin/ogre.cfg
		insopts -m666
		doins Samples/Common/bin/*.cfg
		rm -f "${D}/usr/share/OGRE/Samples/bin"/*.in
		rm -f "${D}/usr/share/OGRE/Samples/bin"/Makefile*
	fi
	dodoc AUTHORS BUGS LINUX.DEV README Docs/README.linux
	if use doc ; then
		dohtml -r Docs 
	else
		dohtml -r Docs/manual
	fi
}