# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator games

MY_PV=$(replace_all_version_separators '_')
MY_P=SecondLife_${MY_PV}
dir=${GAMES_PREFIX_OPT}/${PN}

DESCRIPTION="A 3D MMORPG virtual world entirely built and owned by its residents"
HOMEPAGE="http://secondlife.com/"
SRC_URI="http://secondlife.com/downloads/viewer/${MY_P}.tar.bz2"

LICENSE="as-is"
SLOT="0"

KEYWORDS="~x86"
IUSE=""
RESTRICT="mirror strip"

QA_EXECSTACK="${dir:1}/bin/${PN}-bin
	${dir:1}/lib/libGLU.so.1
	${dir:1}/lib/libkdu_v42R.so
	${dir:1}/lib/libcrypto.so.0.9.7"
QA_TEXTRELS="${dir:1}/lib/libfreetype.so.6
	${dir:1}/lib/libcrypto.so.0.9.7
	${dir:1}/lib/libGLU.so.1"

RDEPEND="dev-libs/libgcrypt
	dev-libs/libgpg-error
	dev-libs/openssl
	media-libs/freetype
	media-libs/libogg
	media-libs/libsdl
	media-libs/libvorbis
	net-libs/gnutls
	net-misc/curl
	sys-libs/glibc
	sys-libs/zlib
	virtual/glu
	virtual/opengl
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"

S=${WORKDIR}/${MY_P}
Ddir=${D}/${dir}
state_dir=${GAMES_STATEDIR}/${PN}

src_install() {
	local d

	insinto "${dir}"
	doins -r * || die "doins * failed"
	dodir "${state_dir}"

	exeinto "${dir}"
	rm -f "${Ddir}/${PN}"
	doexe ${PN} || die "doexe ${PN} failed"
	for d in bin lib ; do
		rm -f "${Ddir}/${d}/*"
		exeinto "${dir}/${d}"
		doexe "${d}"/* || die "doexe ${d} failed"
	done

	cp -rf SecondLife/* "${D}/${state_dir}"
	rm -rf "${Ddir}"/SecondLife

	cd "${D}"
	for d in $(find "${state_dir:1}" -type d) ; do
		keepdir "${d}"
	done
	cd "${S}"

	dosym "${state_dir}" "${dir}"/SecondLife \
		|| die "dosym SecondLife failed"
	dosym "${state_dir}"/lastrun.log "${dir}"/lastrun.log \
		|| die "dosym lastrun.log failed"

	games_make_wrapper ${PN} bin/${PN}-bin "${dir}" "${dir}"/lib
	newicon help/sl_logo.gif ${PN}.gif
	make_desktop_entry ${PN} "Second Life" ${PN}.gif

	prepgamesdirs

	# Need to be able to write within the state directories
	fperms -R g+w "${state_dir}" || die "fperms ${state_dir} failed"
}