mercurial-0.9-r1.ebuild

mercurial-0.9-r1.ebuild (text/plain), 1.60 KB, created by MATSUI Tetsushi on 2006-07-11 12:24:04 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:$

inherit bash-completion distutils elisp-common

MY_PV=${PV//_p/.}

DESCRIPTION="scalable distributed SCM"
HOMEPAGE="http://www.selenic.com/mercurial/"
SRC_URI="http://www.selenic.com/mercurial/release/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha ~amd64 ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc emacs"

DEPEND=">=dev-lang/python-2.3
	doc? (
		app-text/asciidoc
		app-text/xmlto
	)
    emacs? ( virtual/emacs )"

if [[ ${PV} == *_p* ]]; then
	S=${WORKDIR}/mercurial-snapshot
else
	S=${WORKDIR}/${PN}-${MY_PV}
fi

src_compile() {
	distutils_src_compile

	if use doc; then
		cd doc
		local x
		for x in *.?.txt; do
			asciidoc -d manpage -b docbook $x || die
			xmlto man ${x%txt}xml || die
			sed -nie '/./p' ${x%.*} || die
		done
	fi
	if use emacs; then
		cd ${S}/contrib
		elisp-compile mercurial.el || die "Emacs modules failed!"
	fi
}

src_install() {
	distutils_src_install

	dobashcompletion contrib/bash_completion ${PN}

	dodoc CONTRIBUTORS PKG-INFO README *.txt
	cp hgweb*.cgi ${D}/usr/share/doc/${PF}/
	cp -r contrib ${D}/usr/share/doc/${PF}/
	if use doc; then
		doman doc/*.?
	fi
	if use emacs; then
		insinto ${SITELISP}
		doins contrib/mercurial.el*
		elisp-site-file-install ${FILESDIR}/70mercurial-gentoo.el
	fi
}

pkg_postinst() {
	distutils_pkg_postinst
	use emacs && elisp-site-regen
	bash-completion_pkg_postinst
}

pkg_postrm() {
	distutils_pkg_postrm
	# regenerate site-gentoo if we are merged USE=emacs and unmerged
	# USE=-emacs
	has_version virtual/emacs && elisp-site-regen
}