inherit eutils

DESCRIPTION="cmus - ncurses based music player."
SRC_URI="http://onion.dynserv.net/~timo/files/${P}.tar.bz2"
HOMEPAGE="http://onion.dynserv.net/~timo/cmus.html"
SLOT="0"
IUSE="alsa ao arts debug flac oss mad modplug musepack vorbis"

DEPEND="sys-libs/ncurses
	ao? (  media-libs/libao )
	alsa? ( >=media-libs/alsa-lib-0.9.0 )
	arts? ( kde-base/arts )
	flac? ( >=media-libs/flac-1.1.2 )
	mad? ( >=media-libs/libmad-0.14 )
	modplug? ( >=media-libs/libmodplug-0.7 )
	musepack? ( >=media-libs/libmpcdec-1.2 )
	vorbis? ( >=media-libs/libvorbis-1.0 )
	"

RDEPEND=${DEPEND}

LICENSE="GPL-2"
KEYWORDS="~x86 ~ppc ~ppc64 ~amd64"

pkg_setup()
{
	if ! built_with_use sys-libs/ncurses unicode
	then
		einfo "sys-libs/ncurses compiled without the unicode USE flag."
		einfo "Please recompile sys-libs/ncurses with USE=unicode and emerge"
		einfo "cmus again if you experience any problems with UTF-8 or"
		einfo "wide characters."
		epause
	fi
}

my_config()
{
	local value
	use ${1} && value=y || value=n
	myconf="${myconf} ${2}=${value}"
}

src_compile()
{
	local debuglevel myconf

	if use debug
	then
		debuglevel=2
	else
		debuglevel=1
	fi

	myconf="CONFIG_SUN=n"
	my_config ao CONFIG_AO
	my_config alsa CONFIG_ALSA
	my_config arts CONFIG_ARTS
	my_config flac CONFIG_FLAC
	my_config oss CONFIG_OSS
	my_config mad CONFIG_MAD
	my_config modplug CONFIG_MODPLUG
	my_config musepack CONFIG_MPC
	my_config vorbis CONFIG_VORBIS

	./configure prefix=/usr ${myconf} DEBUG=$debuglevel || die

	make ${MAKEOPTS} || die
}

src_install()
{
	make DESTDIR=${D} install install-man || die
	dodoc AUTHORS README
}