# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils python

DESCRIPTION="Object-oriented python bindings for subversion"
HOMEPAGE="http://pysvn.tigris.org/"
SRC_URI="http://pysvn.tigris.org/files/documents/1233/31570/${P}.tar.gz"

LICENSE="Apache-1.1"
SLOT="0"
KEYWORDS="~x86 ~ppc ~amd64"

IUSE="doc"
DEPEND="${DEPEND}
	>=dev-python/pycxx-5.3.5
	>=dev-util/subversion-1.2.0"
RDEPEND=""

S=${WORKDIR}/${P}

src_unpack() {
	local extension_dir
	unpack ${A}
	cd ${S}/Source

	python_version
	einfo "Copying over PyCXX sources..."
	extension_dir="${S}/Import"
	mkdir -p ${extension_dir}/Src
	cp /usr/share/python${PYVER}/CXX/* ${extension_dir}/Src || die "Cannot find PyCXX sources necessary to compile this extension!"

	python setup.py configure --pycxx-dir=${extension_dir} || die "Could not configure ${PN}."
	sed -i -e 's:^\(CCFLAGS=\)\(.*\):\1$(CFLAGS) \2:g' -e 's:^\(CCCFLAGS=\)\(.*\):\1$(CXXFLAGS) \2:g' ${S}/Source/Makefile
}

src_compile() {
	cd ${S}/Source
	emake || die "Could not compile ${PN}."
}

src_install() {
	local base_dir
	local module_dir
	base_dir=${S}/Source/pysvn
	module_dir=/usr/lib/python${PYVER}/site-packages/pysvn
	exeinto ${module_dir}
	doexe ${base_dir}/_pysvn.so
	insinto ${module_dir}
	doins ${base_dir}/__init__.py

	if use doc; then
		for doc in `ls ${S}/Docs/*.{html,js}`; do
			dohtml $doc
        done
	fi
}