Bumped boxbackup ebuild (boxbackup-0.10-r1.ebuild)

boxbackup-0.10-r1.ebuild (text/plain), 2.48 KB, created by Stuart Hickinbottom on 2006-06-19 12:22:09 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/boxbackup/boxbackup-0.10.ebuild,v 1.1 2006/03/05 13:16:02 grobian Exp $

inherit eutils

DESCRIPTION="A completely automatic on-line backup system"
HOMEPAGE="http://www.fluffy.co.uk/boxbackup/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~ppc-macos ~x86"
IUSE="client-only"
DEPEND="sys-libs/zlib
	sys-libs/db
	>=dev-libs/openssl-0.9.7
	>=dev-lang/perl-5.6
	>=sys-devel/autoconf-2.50"
RDEPEND="${DEPEND}
	virtual/mta"

src_unpack() {
	unpack ${A}

	epatch "${FILESDIR}/${P}"-gentoo.patch
	epatch "${FILESDIR}/${P}"-noll.patch
}

src_compile() {
	./bootstrap || die "bootstrap failed"
	econf || die "configure failed"
	make || die
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"
	make DESTDIR="${D}" install-backup-client || die "client install failed"
	use client-only || \
		make DESTDIR="${D}" install-backup-server || die "server install failed"

	dodoc *.txt
	exeinto /etc/init.d
	newexe ${FILESDIR}/bbackupd.rc bbackupd
	use client-only || \
		newexe ${FILESDIR}/bbstored.rc bbstored

	keepdir /etc/boxbackup

	# move executables from /usr/bin to /usr/sbin, as configuration of
	# this is unfortunately not optimal
	mv "${D}/usr/bin" "${D}/usr/sbin" || die "could not move files from bin to sbin"
}

pkg_preinst() {
	if ! use client-only;
	then
		enewgroup bbstored
		enewuser bbstored -1 -1 -1 bbstored
	fi
}

pkg_postinst() {
	while read line; do einfo "${line}"; done <<EOF
After configuring the Box Backup client and/or server, you can start
the daemons using the init scripts /etc/init.d/bbackupd and
/etc/init.d/bbstored.

The configuration files can be found in /etc/boxbackup - this is
different to a non-Portage install (which would use /etc/box).

More information about configuring the client can be found at
${HOMEPAGE}client.html,
and more information about configuring the server can be found at
${HOMEPAGE}server.html.
EOF
	echo

	while read line; do ewarn "${line}"; done <<EOF2
Note that Box Backup 0.10 has changed the client/server protocol
from that used in Box Backup 0.09. This means that both client
server must be upgraded to the same version or you'll experience
connection failures from your clients.

Whilst the client/server protocol has changed, the server
storage format has not. That means that the server can be upgraded
in-place without losing any of the backed-up data it holds.
EOF2
}