# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.0.7-r2.ebuild,v 1.4 2006/03/09 00:43:40 vapier Exp $

inherit eutils flag-o-matic autotools libtool

DESCRIPTION="NFS client and server daemons"
HOMEPAGE="http://nfs.sourceforge.net/"
SRC_URI="mirror://sourceforge/nfs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="nonfsv4 tcpd kerberos"

AT_GNUCONF_UPDATE=no

# kth-krb doesn't provide the right include
# files, and nfs-utils doesn't build against heimdal either, 
# so don't depend on virtual/krb.
# (04 Feb 2005 agriffis)
RDEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=net-nds/portmap-5b-r6
	!nonfsv4? (
		>=dev-libs/libevent-1.0b
		>=dev-libs/libnfsidmap-0.9
		>=dev-libs/librpcsecgss-0.10
	)
	kerberos? ( virtual/krb5 )"
DEPEND="${RDEPEND}
	>=sys-apps/portage-2.0.51"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# getrpcbynumber_r is not in the SuSv3 spec. disable it for uClibc
	epatch "${FILESDIR}"/nfs-utils-1.0.6-uclibc.patch
	
	epatch "${FILESDIR}"/${P}-eepro-support.patch
	epatch "${FILESDIR}"/${P}-nolibs.patch
	epatch "${FILESDIR}"/${P}-CITI_NFS4_ALL-2.patch

	epatch "${FILESDIR}"/${P}-heimdal.patch

	sed -i -e 's#libroken.a#libroken.so#g' aclocal/kerberos5.m4	
#	sed -i -e 's#/lib/#/%{_lib}/#g' aclocal/kerberos5.m4
	AT_M4DIR="aclocal" eautoreconf
}

src_compile() {
	econf \
		--mandir=/usr/share/man \
		--with-statedir=/var/lib/nfs \
		--disable-rquotad \
		--enable-nfsv3 \
		--enable-secure-statd \
		--disable-dependency-tracker \
		$(use_enable !nonfsv4 nfsv4) \
		$(use_enable kerberos gss) \
		$(use_with tcpd tcp-wrappers) \
		|| die "Configure failed"

	# parallel make fails for depend target
	emake || die "Failed to compile"
}

src_install() {
	make DESTDIR="${D}" install || die

	# Don't overwrite existing xtab/etab, install the original
	# versions somewhere safe...  more info in pkg_postinst
	dodir /usr/lib/nfs
	keepdir /var/lib/nfs/{sm,sm.bak}
	mv "${D}"/var/lib/nfs/* "${D}"/usr/lib/nfs
	keepdir /var/lib/nfs

	# Install some client-side binaries in /sbin
	dodir /sbin
	mv "${D}"/usr/sbin/rpc.{lockd,statd} "${D}"/sbin/

	dodoc ChangeLog README
	docinto linux-nfs ; dodoc linux-nfs/*

	insinto /etc
	doins "${FILESDIR}"/exports
	use !nonfsv4 && doins utils/idmapd/idmapd.conf
	use kerberos && newins support/gssapi/SAMPLE_gssapi_mech.conf

	doinitd "${FILESDIR}"/nfs "${FILESDIR}"/nfsmount
	newconfd "${FILESDIR}"/nfs.confd nfs

	# uClibc doesn't provide rpcgen like glibc, so lets steal it from nfs-utils
	if ! use elibc_glibc ; then
		dobin tools/rpcgen/rpcgen || die "rpcgen"
		newdoc tools/rpcgen/README README.rpcgen
	fi
}

pkg_preinst() {
	if [[ -s ${ROOT}/etc/exports ]] ; then
		rm -f "${IMAGE}"/etc/exports
	fi
}

pkg_postinst() {
	# Install default xtab and friends if there's none existing.
	# In src_install we put them in /usr/lib/nfs for safe-keeping, but
	# the daemons actually use the files in /var/lib/nfs.  This fixes
	# bug 30486
	local f
	for f in "${ROOT}"/usr/lib/nfs/*; do
		[[ -f ${ROOT}/var/lib/nfs/${f##*/} ]] && continue
		einfo "Copying default ${f##*/} from /usr/lib/nfs to /var/lib/nfs"
		cp -pPR ${f} "${ROOT}"/var/lib/nfs/
	done
}