warsow-0.11.ebuild

warsow-0.11.ebuild (text/plain), 2.57 KB, created by Paul Bredbury on 2006-05-31 00:02:02 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PV=${PV/_/}
F=${PN}_${MY_PV}_linux.tar.gz
SDK=${PN}_${MY_PV}_sdk.zip

DESCRIPTION="Multiplayer FPS based on the Quake 2 engine"
HOMEPAGE="http://www.warsow.net/"
SRC_URI="http://www.vermaele.be/${PN}/${F}
	http://gamer-convention.de/~${PN}/${F}
	http://wsw.surreal-xenotronic.com/${F}
	ftp://ftp.multiplay.co.uk/pub/games/fps/${PN}/game/linux/${F}
	http://warsow.aditsystems.com/${F}
	http://www.fatalerror.be/${PN}/${F}
	http://warsow.dravennet.de/${MY_PV}/${F}
	ftp://ftp.grolier.fr/pub/games/nofrag/${PN}/${F}
	http://www.vermaele.be/${PN}/${SDK}
	http://gamer-convention.de/~${PN}/${SDK}
	http://wsw.surreal-xenotronic.com/${SDK}
	http://warsow.aditsystems.com/${SDK}
	http://warsow.dravennet.de/${MY_PV}/${SDK}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
RESTRICT="strip"
IUSE=""

RDEPEND="media-libs/jpeg
	>=media-libs/libsdl-1.2.8-r1
	>=media-libs/sdl-sound-1.0.1-r1
	net-misc/curl
	sys-libs/glibc
	sys-libs/zlib
	virtual/opengl
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext
			x11-proto/xf86dgaproto
			x11-proto/xf86vidmodeproto
			x11-proto/xproto )
		virtual/x11 )"
DEPEND="${RDEPEND}
	!games-fps/warsow-bin
	app-arch/unzip"

S=${WORKDIR}/source/source
SDATA=${WORKDIR}/warsow
dir=${GAMES_DATADIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Make fs_usehomedir default to 1 - the game will write to ~/.warsow/
	# Make fs_basepath default to correct path
	sed -i qcommon/files.c \
		-e 's:"fs_usehomedir", "0":"fs_usehomedir", "1":' \
		-e "s:\"fs_basepath\", \"\.\":\"fs_basepath\", \"${dir}\":" \
		|| die "sed files.c failed"

	# Remove precompiled binaries
	rm "${SDATA}"/{warsow{,.x86_64},wswBrowser,wsw_server{,.x86_64}}

	# Remove copy of licence
	rm "${SDATA}"/docs/gnu.txt
}

src_compile() {
	emake BINDIR=release || die "emake failed"
	cp -r release/basewsw "${SDATA}" || die "cp basewsw failed"
}

src_install() {
	local bins="release/warsow release/wsw_server"
	local ext icon="levelshots/wdm1.jpg"

	dogamesbin ${bins} && rm ${bins} || die "dogamesbin failed"

	cd "${SDATA}"

	dodoc docs/*
	rm -r docs

	exeinto "${dir}"/basewsw
	doexe basewsw/*.so && rm basewsw/*.so || die "doexe basewsw failed"

	insinto "${dir}"
	doins -r * || die "doins -r failed"

	# Extract icon - doesn't show in Gnome though
	unzip basewsw/data0.pk3 "${icon}" || die "unzip data0.pk3 failed"
	ext=${icon##*.}
	newicon "${icon}" "${PN}.${ext}" || die "newicon failed"
	make_desktop_entry ${PN} "Warsow" "${PN}.${ext}"

	prepgamesdirs
}