# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator games

# End up with MY_PV=03282k6
DATE=$(get_version_component_range 1-1)
MY_PV=${DATE:4:4}-${DATE:0:4}
MY_PV=${MY_PV/-2006/2k6}

MOD="mitm"

DESCRIPTION="Single-player map trilogy"
HOMEPAGE="http://www.makeittomorning.co.uk"
SRC_URI="mirror://filefront/Doom_III/Resurrection_of_Evil/Maps/Single_Player/make_it_to_morning_${MY_PV}.zip"

LICENSE="as-is"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""
RESTRICT="primaryuri strip"

RDEPEND="games-fps/doom3-roe"
DEPEND="app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/doom3

src_install() {
	insinto "${dir}/${MOD}"
	doins -r * || die "doins failed"

	games_make_wrapper ${PN} \
		"doom3 +set fs_game ${MOD} +set fs_game_base d3xp +map mitm"
	make_desktop_entry ${PN} "Doom III - Make it to Morning (1)" doom3.png
	local n
	for n in {2,3} ; do
		games_make_wrapper ${PN}${n} \
			"doom3 +set fs_game ${MOD} +set fs_game_base d3xp +map mitm${n}"
		make_desktop_entry ${PN}${n} \
			"Doom III - Make it to Morning (${n})" doom3.png
	done

	prepgamesdirs
}