mednafen-0.6.0.ebuild

mednafen-0.6.0.ebuild (text/plain), 1.73 KB, created by trefoil on 2006-05-18 13:41:33 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

MY_SN="mednafen-server"
MY_SV="0.2.2"
DESCRIPTION="An advanced NES, GB/GBC/GBA, TurboGrafx 16/CD, and Lynx emulator"
HOMEPAGE="http://mednafen.com/"
SRC_URI="http://mednafen.com/releases/${P}.tar.bz2
	server? ( http://mednafen.com/support/${MY_SN}-${MY_SV}.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="server debug"

RDEPEND="virtual/opengl
	sys-libs/zlib
	media-libs/libsndfile
	dev-libs/libcdio
	media-libs/libsdl
	media-libs/sdl-net"
	
# The following likely still applies to Mednafen as it uses FCE Ultra code.
# Because of code generation bugs, FCEUltra now depends on a version
# of gcc greater than or equal to GCC 3.2.2.
DEPEND="${RDEPEND}
	>=sys-devel/gcc-3.2.2"

MY_SS="${WORKDIR}/${MY_SN}"
S="${WORKDIR}/${PN}"

# v0.6.0 conf with --disable-nls fails to compile
src_compile() {	
	if use server ; then
		cd "${MY_SS}"
		mv README README.server
		mv standard.conf server.conf.example
		emake || die "emake server failed"
		cd "${S}"
	fi
	
	egamesconf $(use_with debug debugger) \
	--disable-dependency-tracking || die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"

	if use server ; then
		cd "${MY_SS}"
		dogamesbin mednafen-server
		dodoc README.server server.conf.example
		cd "${S}"
	fi

	dodoc AUTHORS README NEWS TODO ChangeLog Documentation/cheats.txt
	prepalldocs
	dohtml Documentation/*

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	if use server ; then
	    echo
	    einfo "Please see README.server and server.conf.example"
		einfo "for information on running the Mednafen netplay server."
	    echo
	fi
}