# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator wxwidgets

MY_MAJ=$(get_version_component_range 1-2)
MY_REV=$(get_version_component_range 3)

SRC_URI="http://downloads.xara.com/opensource/XaraLX-${MY_MAJ}r${MY_REV}.tar.bz2"
DESCRIPTION="GPL'd version of the venerable graphics editor"
HOMEPAGE="http://www.xaraxtreme.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="debug examples nls unicode"

DEPEND="nls? ( >=sys-devel/gettext-0.14.3 )
		>=sys-devel/gcc-3.4.0
		dev-util/pkgconfig
		x11-libs/gtk+
		>=x11-libs/wxGTK-2.6.3_rc2
		>=sys-devel/gettext-0.14.3
		sys-devel/libtool
		>=sys-devel/automake-1.6
		>=sys-devel/autoconf-2.59
		>=media-libs/libpng-1.2.8
		>=media-libs/jpeg-6b
		app-arch/zip
		dev-lang/perl
		sys-apps/coreutils
		dev-util/cvs"
RDEPEND=""

S="${WORKDIR}/XaraLX-${MY_MAJ}r${MY_REV}"
pkg_setup() {
	built_with_use x11-libs/wxGTK unicode || \
		die "Please recompile wxGTK with USE=\"unicode\"."
}

src_compile() {
	export WX_GTK_VER="2.6"
	need-wxwidgets unicode || die

	autoreconf --force --install --symlink

	econf \
		$(use_enable nls) \
		$(use_enable debug) \
		--with-wx-config=${WX_CONFIG} || die "econf failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die "install failed"

	# For lack of configure options and make targets:
	if use examples; then
		insinto /usr/share/${P}/Designs
		doins Designs/*.xar
		insinto /usr/share/${P}/TextDesigns
		doins TextDesigns/*.xar
		insinto /usr/share/${P}/testfiles
		doins testfiles/*.xar
	fi

	# As yet empty but that might change in future versions:
	dodoc AUTHORS ChangeLog NEWS README
}