# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PN="Producer"
DESCRIPTION="Cross-platform OpenGL Library, focused on camera control"
SRC_URI="http://www.openscenegraph.org/downloads/dependencies/${MY_PN}-${PV}.zip"
HOMEPAGE="http://www.openscenegraph.org/"

SLOT=0
LICENSE="OSGPL"
KEYWORDS="~x86"
IUSE="doc examples"

RDEPEND="virtual/opengl
		>=dev-libs/openthreads-1.4.2"
DEPEND="${RDEPEND}
	app-arch/unzip
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${MY_PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i 's/head -1/head -n 1/' Make/instrules \
		|| die "sed (head) failed"

	sed -i "s:OPTF *= .*:OPTF = \"${CXXFLAGS}\":" Make/makedefs \
		|| die "sed (CXXFLAGS) failed"
}

src_compile() {
	emake || die "emake failed"

	if use doc ; then
		doxygen -u doc/doxy.cfg
		doxygen doc/doxy.cfg
	fi
}

src_install() {
	make install INST_LOCATION="${D}"/usr || die "emake failed"

	insinto /usr/$(get_libdir)/pkgconfig
	doins Make/producer.pc

	use doc && dohtml -r doc/Doxygen/html/*

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins -r doc/Tutorial/SourceCode/*
	fi

	dodoc README.txt
}