# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P="sge${PV}"
DESCRIPTION="Graphics extensions library for SDL"
HOMEPAGE="http://www.etek.chalmers.se/~e8cal1/sge/"
SRC_URI="http://www.etek.chalmers.se/~e8cal1/sge/files/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples image truetype"

RDEPEND=">=media-libs/libsdl-1.2
	image? ( >=media-libs/sdl-image-1.2 )
	truetype? ( >=media-libs/freetype-2 )"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}	
	cd "${S}"
	epatch "${FILESDIR}"/${P}-build.patch
	epatch "${FILESDIR}"/${P}-freetype.patch
}

src_compile() {
	yesno() { use $1 && echo y || echo n ; }
	emake \
		USE_IMG=$(yesno image) \
		USE_FT=$(yesno truetype) \
		|| die "emake failed"

	if use examples ; then
		cd examples
		emake -j1 \
			USE_IMG=$(yesno image) \
			USE_FT=$(yesno truetype) \
			|| die "emake (examples) failed"
	fi
}

src_install() {
	make install DESTDIR="${D}" || die

	dodoc README Todo WhatsNew

	use doc && dohtml docs/*

	if use examples ; then
		insinto /usr/share/doc/${PF}
		exeinto /usr/share/doc/${PF}/examples/bin
		doins -r examples
		cd "${D}/usr/share/doc/${PF}/examples"
		mkdir src

		if use truetype ; then
			mv font.ttf bin
			mv basics_c.c src
		else
			rm {basics,blitting,input,alpha,inputdeluxe}.cpp
			rm basics_c.c
			rm font.ttf ttf_readme
		fi

		if use image ; then
			mv sfont.png bin
			mv sfont.cpp src
		else
			rm sfont.*
		fi

		mv *.bmp bin
		mv *.cpp src
		rm Makefile

		for o in *.o ; do
			doexe ${o%.o}
			rm ${o%.o} ${o}
		done
	fi
}