# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils fortran

DESCRIPTION=" Software for evaluating the electrostatic properties of nanoscale biomolecular systems"
LICENSE="GPL-2"
HOMEPAGE="http://agave.wustl.edu/apbs/"
SRC_URI="http://umn.dl.sourceforge.net/sourceforge/apbs/${P}.tar.gz"

SLOT="0"
IUSE="blas mpi"
KEYWORDS="~x86 ~amd64"

DEPEND="blas? ( virtual/blas )
	sys-libs/readline
	dev-libs/maloc
	mpi? ( >=sys-cluster/lam-mpi-6.5.6 )"

pkg_setup() {
	need_fortran g77
}

src_compile() {
	# use blas
	use blas && local myconf="--with-blas=-lblas"

	# configure 
	econf ${myconf} \
	$(use_enable mpi) \
	|| die "configure failed"

	# build
	make || die "make failed"
}

src_install() {

	# install apbs binary
	dobin bin/apbs || die "failed to install apbs binary"

	# fix up and install examples
	sed -e "s|\${bindir}|/usr/bin|" \
		-i examples/ion-pmf/runme || \
		die "failed fixing ion-pmf/runme file"

	sed -e "s|bindir=''|bindir=/usr/bin|" \
		-i examples/point-pmf/runme.sh || \
		die "failed fixing point-pmf/runme.sh"

	insinto /usr/share/doc/${PF}/examples
	doins -r examples/* || die "failed to install examples"

	# install docs
	insinto /usr/share/doc/${PF}/html/programmer
	doins doc/html/programmer/* || die "failed to install html docs"

	insinto /usr/share/doc/${PF}/html/tutorial
	doins doc/html/tutorial/* || die "failed to install html docs"

	insinto /usr/share/doc/${PF}/html/user-guide
	doins doc/html/user-guide/* || die "failed to install html docs"
}