# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/gemhun/gemhun-20031016.ebuild,v 1.5 2004/06/24 23:04:42 agriffis Exp $

inherit eutils flag-o-matic autotools games

DESCRIPTION="A puzzle game about grouping gems of a chosen amount together"
HOMEPAGE="http://gemhun.sourceforge.net/"
SRC_URI="mirror://sourceforge/gemhun/GemHunters-src-${PV}.tar.gz
	mirror://sourceforge/gemhun/fairylands-bin-${PV}.tar.gz
	mirror://sourceforge/gemhun/stars_in_the_night-bin-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE=""

DEPEND="dev-games/kyra
	>=media-libs/sdl-mixer-1.2.1
	virtual/opengl
	sys-libs/ncurses
	media-libs/sdl-net
	media-libs/libpng"

S="${WORKDIR}/GemHunters-${PV}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e "/packageprefix=/s/{prefix/{datadir/" \
		-e "/packagedatadir=/s:share/::" \
		configure.in \
		|| die "sed on configure.in failed"
	sed -i \
		-e "s/prefix/pkgdatadir/" \
		-e "s:@NO_PREFIX_PACKAGE_DATA_DIR@/::" \
		data/gfx/Makefile.am \
		data/sfx/Makefile.am \
		data/music/Makefile.am \
		data/pax/networkscreen/Makefile.am \
		data/pax/title/Makefile.am \
		data/levels/Makefile.am \
		|| die "sed on Makefile failed"
	sed -i \
		-e "s/prefix/pkgdatadir/" \
		-e "s:@NO_PREFIX_PACKAGE_PIXMAPS_DIR@:pixmaps:" \
		pixmaps/Makefile.am \
		|| die "sed on Makefile failed"
	sed -i \
		-e "/gemhun_includedir/d" \
		-e "/EXTRA_DIST/d" \
		-e "s/gemhun_include_DATA/noinst_HEADERS/" \
		include/Makefile.am \
		|| die "sed on Makefile failed"
	sed -i \
		-e "/gemhundocdir/d" \
		-e "/EXTRA_DIST/d" \
		-e "/INSTALL/d" \
		-e "/NEWS/d" \
		-e "/README/d" \
		-e "/AUTHORS/d" \
		-e "/ChangeLog/d" \
		-e "/COPYING/d" \
		-e "s/gemhundoc_DATA/EXTRA_DIST/" \
		Makefile.am \
		|| die "sed on Makefile failed"
	sed -i \
		-e "s/CFLAGS =/AM_CFLAGS =/" \
		-e "s/CXXFLAGS =/AM_CXXFLAGS =/" \
		src/Makefile.am \
		|| die "sed on Makefile failed"
	sed -i \
		-e "/ListenOnPort/d" \
		src/main.cpp \
		|| die "send on main.cpp"
	eautoreconf
}

src_compile() {
	egamesconf \
		|| die "egamesconf failed"
	emake ||  die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die "Install failed"
	dodoc AUTHORS ChangeLog README README.Install TODO
	cp -r ../fairylands "${D}${GAMES_DATADIR}/GemHunters/pax/"
	cp -r ../stars_in_the_night "${D}${GAMES_DATADIR}/GemHunters/pax/"
	doicon pixmaps/${PN}.png
	make_desktop_entry ${PN} "GemHunter" ${PN}.xpm


	prepgamesdirs
}