# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-0.98.ebuild,v 1.4 2005/12/19 18:55:11 spyderous Exp $

inherit distutils eutils multilib

DESCRIPTION="A Python-extensible molecular graphics system."
HOMEPAGE="http://pymol.sourceforge.net/"
SRC_URI="mirror://sourceforge/pymol/${PN}-${PV/./_}rc1-src.tgz"

LICENSE="PSF-2.2"
IUSE=""
SLOT="0"
KEYWORDS="~amd64 ppc x86"

DEPEND="dev-lang/python
	dev-python/pmw
	dev-python/numeric
	dev-lang/tk
	dev-lang/tcl
	media-libs/freetype
	media-libs/libpng
	sys-libs/zlib
	virtual/glut"

src_unpack() {
	unpack ${A}
	cd ${S}
	# Turn off splash screen.  Please do make a project contribution
	# if you are able though.
	[[ -n "$WANT_NOSPLASH" ]] && epatch ${FILESDIR}/nosplash-gentoo.patch
}

src_install() {
	distutils_src_install
	cd ${S}


	#Find python version
	python_version

	PYMOL_PATH=/usr/$(get_libdir)/python${PYVER}/site-packages/pymol


	local sedexp1="s:^PYMOL_PATH.*$:PYMOL_PATH=/usr/share/doc/${PF}:g"
	local sedexp2="s:^python.*$:/usr/bin/python ${PYMOL_PATH}/__init__.py \"\$\@\":g"
	
	sed -e ${sedexp1} -e "${sedexp2}" setup/pymol.com.basic > pymol
	
	
	
	exeinto /usr/bin
	doexe pymol
	dodoc DEVELOPERS CHANGES

	#install examples
	mv examples ${D}/usr/share/doc/${PF}
	
	#install data 
	#in 0.98 data went to /usr/lib/python2.4/site-packages/pymol/pymol_path/data/
	mv data ${D}/usr/share/doc/${PF}
	
	#install test 
	#in 0.98 test went to /usr/lib/python2.4/site-packages/pymol/pymol_path/test
	mv test ${D}/usr/share/doc/${PF}
	
	#install scripts 
	#in 0.98 scripts went to /usr/lib/python2.4/site-packages/pymol/pymol_path/scripts
	mv scripts ${D}/usr/share/doc/${PF}
}