# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games toolchain-funcs

MY_PN=${PN/c/C}
MY_P=${MY_PN}_${PV}

DESCRIPTION="3D chess game with embedded AI and pretty good graphics"
HOMEPAGE="http://pouetchess.sf.net"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}_src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="virtual/opengl
	virtual/glu
	media-libs/libsdl
	media-libs/sdl-image"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e "s:data/:${GAMES_DATADIR}/data/:g" \
		src/globalInfos.h \
		|| die "sed failed"

	sed -i \
		-e 's:^\(Width.*\)\d+$:\1 800:' \
		-e 's:^\(Height.*\)\d+:\1 600:' \
		bin/config.ini \
		|| die "sed failed"

	sed -i \
		-e "s:config.ini:${GAMES_SYSCONFDIR}/pouetchess.conf:" \
		src/globalInfos.cpp \
		|| die "sed failed"
}

src_compile() {
	emake \
		CXX=$(tc-getCXX) \
		CXXFLAGS="${CXXFLAGS} `sdl-config --cflags`" \
		|| die "emake failed"
}

src_install() {
	newgamesbin bin/${MY_PN} ${PN} || die "newgamesbin failed"
	insinto "${GAMES_SYSCONFDIR}"
	newins bin/config.ini pouetchess.conf || die "newins failed"
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r bin/data || die "doins failed"
	prepgamesdirs
}