A ebuild for media-libs/libmikmod-3.1.11-r2 (Added BLFS's sed line)

libmikmod-3.1.11-r2.ebuild (text/plain), 1.37 KB, created by hiyuh on 2006-02-02 19:03:32 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libmikmod/libmikmod-3.1.11-r1.ebuild,v 1.12 2005/05/27 06:40:20 josejx Exp $

inherit flag-o-matic eutils libtool

DESCRIPTION="A library to play a wide range of module formats"
HOMEPAGE="http://mikmod.raphnet.net/"
SRC_URI="http://mikmod.raphnet.net/files/${P}.tar.gz"

LICENSE="|| ( LGPL-2.1 LGPL-2 )"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 mips ppc ~ppc-macos ppc64 sparc x86"
IUSE="oss esd alsa"

DEPEND=">=media-libs/audiofile-0.2.3
	alsa? ( >=media-libs/alsa-lib-0.5.9 )
	esd? ( >=media-sound/esound-0.2.19 )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-m4.patch
	epatch "${FILESDIR}"/${P}-amd64-archdef.patch
	use ppc-macos && elibtoolize
	filter-flags -Os

	# ALSA issues are fixed by sed or so.
	sed -i \
		-e "s/LIBMIKMOD_MICRO_VERSION=10/LIBMIKMOD_MICRO_VERSION=11/" \
		-e "s/sys_asoundlib/alsa_asoundlib/" \
		-e "s/snd_cards/snd_card_load/g" \
		-e "s|sys/asoundlib.h|alsa/asoundlib.h|g" \
		-e "s/^LIBOBJS=/#LIBOBJS=/" \
		configure.in || die
	autoconf || die
}

src_compile() {
	econf \
		--enable-af \
		$(use_enable esd) \
		$(use_enable alsa) \
		$(use_enable oss) \
		|| die
	emake || die
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS NEWS README TODO
	dohtml docs/*.html
}