# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="A small daemon to collect system statistics into RRD files."
HOMEPAGE="http://verplant.org/collectd/"
SRC_URI="http://verplant.org/collectd/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="lm_sensors statgrab hddtemp highres mysql"

DEPEND="
	>=net-analyzer/rrdtool-1.2
	hddtemp? ( >=app-admin/hddtemp )
	lm_sensors? ( >=sys-apps/lm_sensors-2.9.0 )
	statgrab? ( >=sys-libs/libstatgrab-0.10 )
	mysql? ( >=dev-db/mysql-4.1 )"

src_unpack() {
	unpack "${A}"

	cd "${S}"

	epatch ${FILESDIR}/ping-seq-3.7.0.patch
	use highres && epatch ${FILESDIR}/highres-${PV}.patch
}

src_compile() {
	local myopts=''

	use lm_sensors \
		&& myopts="${myopts} --with-lm-sensors" \
		|| myopts="${myopts} --without-lm-sensors"

	use statgrab \
		&& myopts="${myopts} --with-libstatgrab" \
		|| myopts="${myopts} --without-libstatgrab"

	use mysql \
		&& myopts="${myopts} --with-libmysql" \
		|| myopts="${myopts} --without-libmysql"

	./configure \
		--prefix=/usr \
		--host=${CHOST} \
		--mandir=/usr/share/man \
		--infodir=/usr/share/info \
		--datadir=/usr/share \
		--sysconfdir=/etc \
		--localstatedir=/var \
		${myopts} || die "configure failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die install failed
	
	dodoc AUTHORS ChangeLog README NEWS TODO

	docinto contrib
	dodoc contrib/*
	docinto contrib/museum
	dodoc contrib/museum/*

	keepdir /var/lib/collectd

	newinitd ${FILESDIR}/${P}.initd collectd
	newconfd ${FILESDIR}/${P}.confd collectd

	insinto /etc
	newins ${FILESDIR}/${P}.conf collectd.conf
}

pkg_postinst() {
	einfo "Note that collectd now uses a configuration file,"
	einfo "defaulting to /etc/collectd.conf."
	einfo "If you have made any changes to conf.d/collectd,"
	einfo "you should read 'man collectd.conf' and modify the"
	einfo "collectd.conf file accordingly."
}