# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN=${PN/soldieroffortune/sof}

DESCRIPTION="First-person shooter based on the mercenary trade"
HOMEPAGE="http://www.lokigames.com/products/sof/"
SRC_URI="mirror://lokigames/loki_demos/${MY_PN}.run"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="nostrip"

DEPEND="games-util/loki_patch"
RDEPEND="media-libs/openal"

S=${WORKDIR}

src_unpack() {
	unpack_makeself
}

src_install() {
	local dir="${GAMES_PREFIX_OPT}/${MY_PN}"
	local demo="data/demos/sof_demo"
	local exe="sof-bin.x86"

	loki_patch patch.dat data/ || die "loki patch failed"

	insinto "${dir}"
	exeinto "${dir}"
	doins -r "${demo}"/* || die "doins failed"
	doexe "${demo}/${exe}" || die "doexe failed"

	# Replace bad library
	dosym /usr/lib/libSDL.so "${dir}"/libSDL-1.1.so.0 || die

	games_make_wrapper ${MY_PN} "./${exe}" "${dir}" "${dir}"
	newicon "${demo}"/launch/box.png ${MY_PN}.png || die
	make_desktop_entry ${MY_PN} "Soldier of Fortune Demo" ${MY_PN}.png

	prepgamesdirs
}